Distorsion de surface par projection
La projection de Mercator ne préserve pas les surfaces. Il ne s'agit pas d'une projection à superficie égale.
In[1]:=
![Click for copyable input](assets.fr/area-distortion-by-a-projection/In_28.png)
GeoProjectionData["Mercator", "EqualArea"]
Out[1]=
![](assets.fr/area-distortion-by-a-projection/O_19.png)
La superficie de l'Afrique est plus de 14 fois supérieure à la surface du Groenland.
In[2]:=
![Click for copyable input](assets.fr/area-distortion-by-a-projection/In_29.png)
GeoArea[Entity["GeographicRegion", "Africa"]]/
GeoArea[Entity["Country", "Greenland"]]
Out[2]=
![](assets.fr/area-distortion-by-a-projection/O_20.png)
Cependant, dans une projection de Mercator, l'Afrique et le Groenland semblent avoir des tailles similaires.
In[3]:=
![Click for copyable input](assets.fr/area-distortion-by-a-projection/In_30.png)
GeoGraphics[{GeoStyling[Green],
Polygon[Entity["Country", "Greenland"]], GeoStyling[Red],
Polygon[Entity["GeographicRegion", "Africa"]]},
GeoProjection -> "Mercator", GeoRange -> "World",
GeoBackground -> "Satellite"]
Out[3]=
![](assets.fr/area-distortion-by-a-projection/O_21.png)
Utilisez une projection équivalente, comme celle de Mollweide, pour représenter de manière plus appropriée les tailles relatives.
In[4]:=
![Click for copyable input](assets.fr/area-distortion-by-a-projection/In_31.png)
GeoProjectionData["Mollweide", "EqualArea"]
Out[4]=
![](assets.fr/area-distortion-by-a-projection/O_22.png)
In[5]:=
![Click for copyable input](assets.fr/area-distortion-by-a-projection/In_32.png)
GeoGraphics[{GeoStyling[Green],
Polygon[Entity["Country", "Greenland"]], GeoStyling[Red],
Polygon[Entity["GeographicRegion", "Africa"]]},
GeoProjection -> "Mollweide", GeoRange -> "World",
GeoBackground -> "Satellite"]
Out[5]=
![](assets.fr/area-distortion-by-a-projection/O_23.png)