¿Cuánto pesa?
El peso de un objeto en un campo gravitacional es el producto de su masa y el valor del campo gravitacional en el punto del objeto. En la superficie de la Tierra el campo gravitacional no es constante y, por lo tanto, el mismo objeto pesa distinto en distintas locaciones. Este ejemplo explora la variabilidad de la magnitud del campo gravitacional con elevación y latitud.
GeogravityModelData calcula varias propiedades del campo gravitacional de la Tierra en una ubicación dada.
![Click for copyable input](assets.es/how-much-does-it-weigh/In_98.png)
GeogravityModelData[GeoPosition[{0, 0}]]
![](assets.es/how-much-does-it-weigh/O_81.png)
Esta utiliza elevación topográfica proporcionada por GeoElevationData.
![Click for copyable input](assets.es/how-much-does-it-weigh/In_99.png)
GeoElevationData[GeoPosition[{0, 0}]]
![](assets.es/how-much-does-it-weigh/O_82.png)
Ignorando otros efectos, el campo gravitacional es generalmente más pequeño para una ubicación con latitud similar pero con mayor elevación.
![Click for copyable input](assets.es/how-much-does-it-weigh/In_100.png)
GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]
![](assets.es/how-much-does-it-weigh/O_83.png)
![Click for copyable input](assets.es/how-much-does-it-weigh/In_101.png)
GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]];
{GeoElevationData[%, UnitSystem -> "Metric"],
GeogravityModelData[%, "Magnitude"]}
![](assets.es/how-much-does-it-weigh/O_84.png)
Calcule los valores del campo gravitacional en puntos equidistantes en el ecuador.
![Click for copyable input](assets.es/how-much-does-it-weigh/In_102.png)
equatorialgravity =
GeogravityModelData[{GeoPosition[{0, -180}], GeoPosition[{5, 180}]},
"Magnitude"][[1]]
![](assets.es/how-much-does-it-weigh/O_85.png)
![Click for copyable input](assets.es/how-much-does-it-weigh/In_103.png)
ListPlot[equatorialgravity, Joined -> True]
![](assets.es/how-much-does-it-weigh/O_86.png)
En el siguiente histograma, existen dos picos principales correspondientes a las áreas terrestres y al fondo de los océanos.
![Click for copyable input](assets.es/how-much-does-it-weigh/In_104.png)
Histogram[equatorialgravity, 20]
![](assets.es/how-much-does-it-weigh/O_87.png)
Superponga la magnitud del campo gravitacional en un mapa de relieve de la Tierra.
![Click for copyable input](assets.es/how-much-does-it-weigh/In_105.png)
equatorialgravityplot =
ListPlot[equatorialgravity, Axes -> False, Joined -> True,
AspectRatio -> 1/8, PlotRangePadding -> None, ImagePadding -> None,
ImageSize -> 400, PlotStyle -> Red];
![Click for copyable input](assets.es/how-much-does-it-weigh/In_106.png)
worldmap =
GeoGraphics[GeoPath["Equator"], GeoRange -> "World",
ImageSize -> 400, GeoBackground -> "ReliefMap"];
![Click for copyable input](assets.es/how-much-does-it-weigh/In_107.png)
Overlay[{worldmap, equatorialgravityplot}, Alignment -> Center]
![](assets.es/how-much-does-it-weigh/O_88.png)
Para mostrar la variabilidad de la latitud, promediamos la magnitud del campo gravitacional sobre la longitud, y representamos el resultado contra la latitud.
![Click for copyable input](assets.es/how-much-does-it-weigh/In_108.png)
gravity =
Mean /@ GeogravityModelData[{GeoPosition[{-90, -180}],
GeoPosition[{90, 180}]}, "Magnitude"];
La Antártida tiene un efecto obvio para las latitudes bajas, debido a la elevación agregada.
![Click for copyable input](assets.es/how-much-does-it-weigh/In_109.png)
ListPlot[gravity, DataRange -> {-90, 90}]
![](assets.es/how-much-does-it-weigh/O_89.png)
![Click for copyable input](assets.es/how-much-does-it-weigh/In_110.png)
MinMax[gravity]
![](assets.es/how-much-does-it-weigh/O_90.png)
Por lo tanto, pueden haber cambios en el orden de 0.5% en el peso de un objeto dado, dependiendo de donde lo midamos.
![Click for copyable input](assets.es/how-much-does-it-weigh/In_111.png)
MinMax[gravity];
1 - First[%]/Last[%]