Mercator esférico o elipsoidal
La proyección de Mercator produce distintos resultados con un modelo esférico de la Tierra, que con uno elipsoidal. Wolfram Language le permite trabajar con ambas situaciones.
La proyección utilizada en la mayoría de servidores web de mapas utiliza un modelo esférico de la Tierra y, por lo general, se llama "web Mercator".
In[1]:=
![Click for copyable input](assets.es/spherical-or-ellipsoidal-mercator/In_74.png)
webMercator = {"Mercator",
"ReferenceModel" -> GeodesyData["WGS84", "SemimajorAxis"]}
Out[1]=
![](assets.es/spherical-or-ellipsoidal-mercator/O_60.png)
In[2]:=
![Click for copyable input](assets.es/spherical-or-ellipsoidal-mercator/In_75.png)
ellipMercator = {"Mercator", "ReferenceModel" -> "WGS84"}
Out[2]=
![](assets.es/spherical-or-ellipsoidal-mercator/O_61.png)
Transforme la ubicación de la Universidad de Oxford usando ambas proyecciones.
In[3]:=
![Click for copyable input](assets.es/spherical-or-ellipsoidal-mercator/In_76.png)
p = GeoPosition[
Entity["University", "UniversityOfOxfordUnitedKingdom36022"]]
Out[3]=
![](assets.es/spherical-or-ellipsoidal-mercator/O_62.png)
In[4]:=
![Click for copyable input](assets.es/spherical-or-ellipsoidal-mercator/In_77.png)
GeoGridPosition[p, webMercator][[1]]
Out[4]=
![](assets.es/spherical-or-ellipsoidal-mercator/O_63.png)
In[5]:=
![Click for copyable input](assets.es/spherical-or-ellipsoidal-mercator/In_78.png)
GeoGridPosition[p, ellipMercator][[1]]
Out[5]=
![](assets.es/spherical-or-ellipsoidal-mercator/O_64.png)
Existe una diferencia vertical correspondiente a más de 33 kilómetros en las coordenadas hacia el norte.
In[6]:=
![Click for copyable input](assets.es/spherical-or-ellipsoidal-mercator/In_79.png)
GeoGridPosition[p, webMercator][[1]];
GeoGridPosition[p, ellipMercator][[1]];
%% - %
Out[6]=
![](assets.es/spherical-or-ellipsoidal-mercator/O_65.png)
Por ejemplo, trace los respectivos mapas del Reino Unido e Irlanda, los cuales parecen casi idénticos.
In[7]:=
![Click for copyable input](assets.es/spherical-or-ellipsoidal-mercator/In_80.png)
webmap = GeoGraphics[{FaceForm[], EdgeForm[Red],
Polygon[{Entity["Country", "UnitedKingdom"],
Entity["Country", "Ireland"]}], Red, Point[p]},
GeoProjection -> webMercator, GeoBackground -> None][[1]]
Out[7]=
![](assets.es/spherical-or-ellipsoidal-mercator/O_66.png)
In[8]:=
![Click for copyable input](assets.es/spherical-or-ellipsoidal-mercator/In_81.png)
ellipmap =
GeoGraphics[{FaceForm[], EdgeForm[Blue],
Polygon[{Entity["Country", "UnitedKingdom"],
Entity["Country", "Ireland"]}], Blue, Point[p]},
GeoProjection -> ellipMercator, GeoBackground -> None][[1]]
Out[8]=
![](assets.es/spherical-or-ellipsoidal-mercator/O_67.png)
Sin embargo, cuando se superponen en el mismo mapa, podemos ver claramente la diferencia.
In[9]:=
![Click for copyable input](assets.es/spherical-or-ellipsoidal-mercator/In_82.png)
Show[webmap, ellipmap]
Out[9]=
![](assets.es/spherical-or-ellipsoidal-mercator/O_68.png)