Quanto isso pesa?
O peso de um objeto num campo gravitacional é o produto da sua massa e o valor do campo gravitacional no ponto do objeto. Na superfície da Terra, o campo gravitacional não é constante, assim, o mesmo objeto tem pesos diferentes em diferentes localizações. Este exemplo explora a variação da magnitude do campo gravitacional com elevação e latitude.
GeogravityModelData calcula várias propriedades do campo gravitacional da Terra em um determinada localização.
![Click for copyable input](assets.pt-br/how-much-does-it-weigh/In_98.png)
GeogravityModelData[GeoPosition[{0, 0}]]
![](assets.pt-br/how-much-does-it-weigh/O_81.png)
Este usa elevação topográfica fornecida por GeoElevationData.
![Click for copyable input](assets.pt-br/how-much-does-it-weigh/In_99.png)
GeoElevationData[GeoPosition[{0, 0}]]
![](assets.pt-br/how-much-does-it-weigh/O_82.png)
Ignorando outros efeitos, o campo gravitacional é geralmente menor para uma localização com latitude semelhante, mas elevação maior.
![Click for copyable input](assets.pt-br/how-much-does-it-weigh/In_100.png)
GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]]
![](assets.pt-br/how-much-does-it-weigh/O_83.png)
![Click for copyable input](assets.pt-br/how-much-does-it-weigh/In_101.png)
GeoPosition[Entity["City", {"Quito", "Pichincha", "Ecuador"}]];
{GeoElevationData[%, UnitSystem -> "Metric"],
GeogravityModelData[%, "Magnitude"]}
![](assets.pt-br/how-much-does-it-weigh/O_84.png)
Calcule a magnitude dos valores do campo gravitacional em pontos equidistantes na linha do equador.
![Click for copyable input](assets.pt-br/how-much-does-it-weigh/In_102.png)
equatorialgravity =
GeogravityModelData[{GeoPosition[{0, -180}], GeoPosition[{5, 180}]},
"Magnitude"][[1]]
![](assets.pt-br/how-much-does-it-weigh/O_85.png)
![Click for copyable input](assets.pt-br/how-much-does-it-weigh/In_103.png)
ListPlot[equatorialgravity, Joined -> True]
![](assets.pt-br/how-much-does-it-weigh/O_86.png)
No histograma a seguir, existem dois picos principais, correspondentes às áreas na terra e ao fundo dos oceanos.
![Click for copyable input](assets.pt-br/how-much-does-it-weigh/In_104.png)
Histogram[equatorialgravity, 20]
![](assets.pt-br/how-much-does-it-weigh/O_87.png)
Sobreponha a magnitude do campo gravitacional sobre um mapa de relevo da Terra.
![Click for copyable input](assets.pt-br/how-much-does-it-weigh/In_105.png)
equatorialgravityplot =
ListPlot[equatorialgravity, Axes -> False, Joined -> True,
AspectRatio -> 1/8, PlotRangePadding -> None, ImagePadding -> None,
ImageSize -> 400, PlotStyle -> Red];
![Click for copyable input](assets.pt-br/how-much-does-it-weigh/In_106.png)
worldmap =
GeoGraphics[GeoPath["Equator"], GeoRange -> "World",
ImageSize -> 400, GeoBackground -> "ReliefMap"];
![Click for copyable input](assets.pt-br/how-much-does-it-weigh/In_107.png)
Overlay[{worldmap, equatorialgravityplot}, Alignment -> Center]
![](assets.pt-br/how-much-does-it-weigh/O_88.png)
Para mostrar a variação com a latitude, nós calculamos a média do campo de gravidade pela longitude, e representamos o resultado em relação a latitude.
![Click for copyable input](assets.pt-br/how-much-does-it-weigh/In_108.png)
gravity =
Mean /@ GeogravityModelData[{GeoPosition[{-90, -180}],
GeoPosition[{90, 180}]}, "Magnitude"];
A Antártida tem um efeito óbvio para latitudes baixas, devido à elevação aumentada.
![Click for copyable input](assets.pt-br/how-much-does-it-weigh/In_109.png)
ListPlot[gravity, DataRange -> {-90, 90}]
![](assets.pt-br/how-much-does-it-weigh/O_89.png)
![Click for copyable input](assets.pt-br/how-much-does-it-weigh/In_110.png)
MinMax[gravity]
![](assets.pt-br/how-much-does-it-weigh/O_90.png)
Por isso, podem acontecer alterações da ordem de 0,5% no peso de um dado objeto, dependendo de onde é feita a medição.
![Click for copyable input](assets.pt-br/how-much-does-it-weigh/In_111.png)
MinMax[gravity];
1 - First[%]/Last[%]