Tempo e distância de uma viagem
Calcule a distância e a duração de uma viagem.
Viaje entre duas cidades distantes.
In[1]:=
cities = {Entity["City", {"Lisbon", "Lisboa", "Portugal"}],
Entity["City", {"Beijing", "Beijing", "China"}]};
Esta é a distância geodésica entre elas.
In[2]:=
GeoDistance[cities]
Out[2]=
Esta é a distância de viagem calculada.
In[3]:=
TravelDistance[cities]
Out[3]=
E este é o tempo de duração estimado, dirigindo continuamente, sem paradas.
In[4]:=
TravelTime[cities]
Out[4]=
Este objeto contém a lista de instruções da viagem.
In[5]:=
td = TravelDirections[{Entity[
"City", {"Lisbon", "Lisboa", "Portugal"}],
Entity["City", {"Beijing", "Beijing", "China"}]}]
Out[5]=
Represente a trajetória (em vermelho) em um mapa Mercator, e compare com a trajetória geodésica (em azul), que é mais curto, como vimos antes.
In[6]:=
GeoGraphics[{Thick, Red, GeoPath[td], Blue,
GeoPath[{Entity["City", {"Lisbon", "Lisboa", "Portugal"}],
Entity["City", {"Beijing", "Beijing", "China"}]}]},
GeoProjection -> "Mercator", GeoGridLines -> Automatic]
Out[6]=
Uma projeção azimutal mostra mais claramente que a geodésica é mais curta que o trajeto de viagem.
In[7]:=
GeoGraphics[{Thick, Red, GeoPath[td], Blue,
GeoPath[{Entity["City", {"Lisbon", "Lisboa", "Portugal"}],
Entity["City", {"Beijing", "Beijing", "China"}]}]},
GeoProjection -> "Mercator", GeoGridLines -> Automatic];
Show[%, GeoProjection -> "LambertAzimuthal", GeoZoomLevel -> 4]
Out[7]=