Reconocimiento de imágenes usando aprendizaje profundo
El aprendizaje profundo puede ser aplicado exitosamente a muchos problemas de procesamiento de imágenes y visión por medio de la computación. Usando NetChain y NetTrain, usted puede definir y entrenar una red neuronal que clasifique a un dígito escrito a mano dada una imagen.
Obtenga datos de entrenamiento y validación de la base de datos de dígitos escritos a mano MNIST.
In[1]:=
![Click for copyable input](assets.es/image-recognition-using-deep-learning/In_34.png)
resource = ResourceObject["MNIST"];
trainingData = ResourceData[resource, "TrainingData"];
testData = ResourceData[resource, "TestData"];
In[2]:=
![Click for copyable input](assets.es/image-recognition-using-deep-learning/In_35.png)
RandomSample[trainingData, 5]
Out[2]=
![](assets.es/image-recognition-using-deep-learning/O_20.png)
Diseñe una red neuronal de convolución creada para reconocer imágenes en escala de grises 28×28.
In[3]:=
![Click for copyable input](assets.es/image-recognition-using-deep-learning/In_36.png)
lenet = NetChain[
{ConvolutionLayer[20, 5], Ramp, PoolingLayer[2, 2],
ConvolutionLayer[50, 5], Ramp, PoolingLayer[2, 2], FlattenLayer[],
500, Ramp, 10, SoftmaxLayer[]},
"Output" -> NetDecoder[{"Class", Range[0, 9]}],
"Input" -> NetEncoder[{"Image", {28, 28}, "Grayscale"}]
]
Out[3]=
![](assets.es/image-recognition-using-deep-learning/O_21.png)
Entrene la red durante tres rondas.
In[4]:=
![Click for copyable input](assets.es/image-recognition-using-deep-learning/In_37.png)
lenet = NetTrain[lenet, trainingData, ValidationSet -> testData,
MaxTrainingRounds -> 3];
Out[4]=
![](assets.es/image-recognition-using-deep-learning/O_22.png)
Evalúe la red entrenada directamente en imágenes muestreadas de forma aleatoria del conjunto de validación.
In[5]:=
![Click for copyable input](assets.es/image-recognition-using-deep-learning/In_38.png)
imgs = Keys @ RandomSample[testData, 5];
Thread[imgs -> lenet[imgs]]
Out[5]=
![](assets.es/image-recognition-using-deep-learning/O_23.png)