利用深度学习进行图像识别
可将深度学习成功用于许多图像处理和计算机视觉问题. 通过使用 NetChain 和 NetTrain,可以定义并训练能够将图像中给出的手写数字分类的神经网络.
从 MNIST 手写数字数据库中获取用来训练和验证的数据.
In[1]:=
![Click for copyable input](assets.zh/image-recognition-using-deep-learning/In_34.png)
resource = ResourceObject["MNIST"];
trainingData = ResourceData[resource, "TrainingData"];
testData = ResourceData[resource, "TestData"];
In[2]:=
![Click for copyable input](assets.zh/image-recognition-using-deep-learning/In_35.png)
RandomSample[trainingData, 5]
Out[2]=
![](assets.zh/image-recognition-using-deep-learning/O_20.png)
设计一个可以用来识别 28×28 灰度图像的卷积神经网络.
In[3]:=
![Click for copyable input](assets.zh/image-recognition-using-deep-learning/In_36.png)
lenet = NetChain[
{ConvolutionLayer[20, 5], Ramp, PoolingLayer[2, 2],
ConvolutionLayer[50, 5], Ramp, PoolingLayer[2, 2], FlattenLayer[],
500, Ramp, 10, SoftmaxLayer[]},
"Output" -> NetDecoder[{"Class", Range[0, 9]}],
"Input" -> NetEncoder[{"Image", {28, 28}, "Grayscale"}]
]
Out[3]=
![](assets.zh/image-recognition-using-deep-learning/O_21.png)
对神经网络进行三轮训练.
In[4]:=
![Click for copyable input](assets.zh/image-recognition-using-deep-learning/In_37.png)
lenet = NetTrain[lenet, trainingData, ValidationSet -> testData,
MaxTrainingRounds -> 3];
Out[4]=
![](assets.zh/image-recognition-using-deep-learning/O_22.png)
直接对从验证数据集中随机抽取的图像运行训练过的网络.
In[5]:=
![Click for copyable input](assets.zh/image-recognition-using-deep-learning/In_38.png)
imgs = Keys @ RandomSample[testData, 5];
Thread[imgs -> lenet[imgs]]
Out[5]=
![](assets.zh/image-recognition-using-deep-learning/O_23.png)