시간의 흐름에 따른 우주의 구성 모델링하기: Wolfram Language 11의 신기능

‹›

시간의 흐름에 따른 우주의 구성 모델링하기

표준 ΛCDM (람다시디엠 모형) 모델을 기반으로 시간의 흐름에 따라 우주의 구성이 어떻게 변화 하는지를 조사합니다.

1000년부터 년에 걸쳐 우주의 다양한 나이의 암흑 에너지, 물질, 방사선의 밀도 비율 값을 계산합니다.

In[1]:=

ages = Quantity[10^Range[3, 11, 0.2], "Years"];

In[2]:=

darkenergy = 
  Table[UniverseModelData[t, "DarkEnergyDensityRatio"], {t, ages}];
matter = Table[
   UniverseModelData[t, "MatterEnergyDensityRatio"], {t, ages}];
radiation = 
  Table[UniverseModelData[t, "RadiationEnergyDensityRatio"], {t, 
    ages}];

우주의 현재 나이를 수직선으로 표시한 세가지 구성 요소에 대해 시간에 따른 진화를 나타냅니다. 현재, 최대 구성 요소는 암흑 에너지입니다.

전체 Wolfram 언어 입력 표시하기

In[3]:=

data = {
   Transpose[{ages, darkenergy}],
   Transpose[{ages, darkenergy + matter}],
   Transpose[{ages, darkenergy + matter + radiation}]
   };
ListLogLinearPlot[data,
 PlotRange -> All,
 Joined -> True,
 Filling -> {1 -> Axis, 2 -> {1}, 3 -> {2}},
 FrameLabel -> Automatic,
 GridLines -> {{13.8*10^9}, None},
 PlotRangePadding -> 0,
 Frame -> True, 
 PlotLegends -> {"DarkEnergyDensity", "MatterEnergyDensity", 
   "RadiationEnergyDensity"}]

Out[3]=

배경 복사의 온도가 273 K에서 373 K 사이였던 시기 (우주의 "거주 가능 기간")를 알아봅니다.

In[4]:=

period = t /. 
    FindRoot[
     Quantity[#, "Kelvins"] == 
      UniverseModelData[t, "RadiationTemperature"], {t, 
      Quantity[1, "Megayears"]}, Evaluated -> False] & /@ {273, 373}

Out[4]=

In[5]:=

Grid[{#, UniverseModelData[#, "RadiationTemperature"]} & /@ 
  Through[{Min, Mean, Max}[period]], Dividers -> All]

Out[5]=

Wolfram 언어™

시간의 흐름에 따른 우주의 구성 모델링하기

관련 예제