Die Beliebtheit von Namen verfolgen
Ermitteln Sie die beliebtesten Mädchennamen in den USA und deren Ranking im Laufe der Zeit.
In[1]:=
![Click for copyable input](assets.de/track-the-popularity-of-names/In_28.png)
girls = SortBy[
EntityList[
EntityClass[
"GivenName", {"Gender" -> "Female",
"Rank" -> Interval[{1, 10}]}]], #["Rank"] &]
Out[1]=
![](assets.de/track-the-popularity-of-names/O_26.png)
In[2]:=
![Click for copyable input](assets.de/track-the-popularity-of-names/In_29.png)
ranksgirls =
Table[EntityValue[name,
Dated[EntityProperty["GivenName", "Rank"], All]], {name, girls}];
Plotten Sie das Ranking der letzten 50 Jahre auf einer Logskala, die den beliebtesten Namen ganz oben anzeigt.
In[3]:=
![Click for copyable input](assets.de/track-the-popularity-of-names/In_30.png)
DateListStepPlot[ranksgirls,
ScalingFunctions -> {-Log[#] &, Exp[-#] &}, PlotLegends -> girls,
PlotTheme -> "Business", ImageSize -> 475,
PlotRange -> {{DateObject[{1965}], DateObject[{2015}]}, All}]
Out[3]=
![](assets.de/track-the-popularity-of-names/O_27.png)
In[4]:=
![Click for copyable input](assets.de/track-the-popularity-of-names/In_31.png)
boys = SortBy[
EntityList[
EntityClass[
"GivenName", {"Gender" -> "Male",
"Rank" -> Interval[{1, 10}]}]], #["Rank"] &];
In[5]:=
![Click for copyable input](assets.de/track-the-popularity-of-names/In_32.png)
ranksboys =
Table[EntityValue[name,
Dated[EntityProperty["GivenName", "Rank"], All]], {name, boys}];
Was das Ranking der Jungennamen betrifft, waren einige Namen im Laufe der Zeit gleichbleibend beliebt.
In[6]:=
![Click for copyable input](assets.de/track-the-popularity-of-names/In_33.png)
DateListStepPlot[ranksboys,
ScalingFunctions -> {-Log[#] &, Exp[-#] &}, PlotLegends -> boys,
PlotTheme -> "Business", ImageSize -> 475,
PlotRange -> {{DateObject[{1965}], DateObject[{2015}]}, All}]
Out[6]=
![](assets.de/track-the-popularity-of-names/O_28.png)