Estude as vibrações de uma corda esticada
Estude as vibrações de uma corda esticada usando a equação de onda.
In[1]:=
![Click for copyable input](assets.pt-br/study-the-vibrations-of-a-stretched-string/In_77.png)
weqn = D[u[x, t], {t, 2}] == D[u[x, t], {x, 2}];
Especifique que os extremos da corda permaneçam fixos durante as vibrações.
In[2]:=
![Click for copyable input](assets.pt-br/study-the-vibrations-of-a-stretched-string/In_78.png)
bc = {u[0, t] == 0, u[\[Pi], t] == 0};
Dê os valores iniciais em diferentes pontos da corda.
In[3]:=
![Click for copyable input](assets.pt-br/study-the-vibrations-of-a-stretched-string/In_79.png)
ic = {u[x, 0] == x^2 (\[Pi] - x),
\!\(\*SuperscriptBox[\(u\),
TagBox[
RowBox[{"(",
RowBox[{"0", ",", "1"}], ")"}],
Derivative],
MultilineFunction->None]\)[x, 0] == 0};
Resolva o problema de valor inicial e de contorno.
In[4]:=
![Click for copyable input](assets.pt-br/study-the-vibrations-of-a-stretched-string/In_80.png)
dsol = DSolve[{weqn, bc, ic}, u, {x, t}] /. {K[1] -> m}
Out[4]=
![](assets.pt-br/study-the-vibrations-of-a-stretched-string/O_36.png)
Extraia quatro termos da soma de Inactive.
In[5]:=
![Click for copyable input](assets.pt-br/study-the-vibrations-of-a-stretched-string/In_81.png)
asol[x_, t_] = u[x, t] /. dsol[[1]] /. {\[Infinity] -> 4} // Activate
Out[5]=
![](assets.pt-br/study-the-vibrations-of-a-stretched-string/O_37.png)
Cada termo na soma representa uma onda estacionária.
In[6]:=
![Click for copyable input](assets.pt-br/study-the-vibrations-of-a-stretched-string/In_82.png)
Table[Show[
Plot[Table[asol[x, t][[m]], {t, 0, 4}] // Evaluate, {x, 0, Pi},
Ticks -> False], ImageSize -> 150], {m, 4}]
Out[6]=
![](assets.pt-br/study-the-vibrations-of-a-stretched-string/O_38.png)
Visualize a vibração da corda.
In[7]:=
![Click for copyable input](assets.pt-br/study-the-vibrations-of-a-stretched-string/In_83.png)
Animate[Plot[asol[x, t], {x, 0, \[Pi]}, PlotRange -> {-5, 5},
ImageSize -> Medium, PlotStyle -> Red], {t, 0, 2 Pi},
SaveDefinitions -> True]
![](assets.pt-br/study-the-vibrations-of-a-stretched-string/swf_4.png)