Túneis
TunnelData fornece informações sobre túneis, tais como o seu comprimento e a localização.
![Click for copyable input](assets.pt-br/tunnels/In_55.png)
tunnels = TunnelData[];
![Click for copyable input](assets.pt-br/tunnels/In_56.png)
Length[tunnels]
![](assets.pt-br/tunnels/O_47.png)
Para cada túnel, ache o seu comprimento e localização dada por país ou países.
![Click for copyable input](assets.pt-br/tunnels/In_57.png)
rawData = TunnelData[tunnels, {"Countries", "Length"}];
Limpe os dados para remover os valores que faltam.
![Click for copyable input](assets.pt-br/tunnels/In_58.png)
data = DeleteMissing[rawData, 1, 2];
Converta os dados de comprimento para milhas.
![Click for copyable input](assets.pt-br/tunnels/In_59.png)
data[[All, 2]] = UnitConvert[N[data[[All, 2]]], "Miles"];
![Click for copyable input](assets.pt-br/tunnels/In_60.png)
lengths = data[[All, 2]];
![Click for copyable input](assets.pt-br/tunnels/In_61.png)
MinMax[lengths]
![](assets.pt-br/tunnels/O_48.png)
![Click for copyable input](assets.pt-br/tunnels/In_62.png)
h = Histogram[lengths, {1, 12, .5}, PDF, FrameLabel -> Automatic,
PlotTheme -> "Detailed"]
![](assets.pt-br/tunnels/O_49.png)
Os dados podem ser descritos por uma mistura de distribuições de cauda longa.
![Click for copyable input](assets.pt-br/tunnels/In_63.png)
dist = MixtureDistribution[{w1,
w2}, {ParetoDistribution[a1, a2, a3, a4],
WeibullDistribution[b1, b2]}];
![Click for copyable input](assets.pt-br/tunnels/In_64.png)
edist = EstimatedDistribution[lengths, dist]
![](assets.pt-br/tunnels/O_50.png)
Teste a bondade de ajuste com relação as distribuições de mistura da família paramétrica.
![Click for copyable input](assets.pt-br/tunnels/In_65.png)
DistributionFitTest[lengths, dist, "TestDataTable"]
![](assets.pt-br/tunnels/O_51.png)
Faça o gráfico da PDF da distribuição ajustada com relação ao histograma.
![Click for copyable input](assets.pt-br/tunnels/In_66.png)
Show[h, Plot[PDF[edist, Quantity[x, "Miles"]], {x, 1, 12},
PlotRange -> All] // Quiet]
![](assets.pt-br/tunnels/O_52.png)
Visualize as localizações dos túneis.
Agrupe por país.
![Click for copyable input](assets.pt-br/tunnels/In_67.png)
res = GroupBy[data, First, Flatten[Take[#, All, -1]] &];
Alguns túneis estão localizados em mais de um país.
![Click for copyable input](assets.pt-br/tunnels/In_68.png)
shared = Select[Keys[res], Length[#] > 1 &]
![](assets.pt-br/tunnels/O_53.png)
Distribua os túneis compartilhados e selecione os países que têm pelo menos 10 túneis. Faça o gráfico de distribuição de comprimento.
![](assets.pt-br/tunnels/O_54.png)
A quilometragem total dos túneis por país com túneis compartilhados incluídos no comprimento total para cada país.
![](assets.pt-br/tunnels/O_55.png)