Réacteurs nucléaires dans le monde
NuclearReactorData fournit des données sur les réacteurs nucléaires connus dans le monde entier. Certains d'entre eux ont déjà été fermés, comme celui de Tchernobyl. Vous pouvez sélectionner les réacteurs qui sont actuellement opérationnels pour l'analyse des ressources énergétiques nucléaires.
![Click for copyable input](assets.fr/world-nuclear-reactors/In_74.png)
reactors = NuclearReactorData[];
![Click for copyable input](assets.fr/world-nuclear-reactors/In_75.png)
active = Keys@
Select[EntityValue["NuclearReactor", "Status",
"EntityAssociation"], # === "operational" &];
Extrayez la production annuelle d'énergie et le pays d'implantation.
![Click for copyable input](assets.en/world-nuclear-reactors/In_76.png)
annualproduction =
NuclearReactorData[active, "AnnualEnergyProduction"];
countries = Map[First, NuclearReactorData[active, "Countries"]];
Créez un jeu de données et supprimez les points de données qui contiennent des valeurs manquantes. Le nombre de réacteurs en fonctionnement est supérieur à 400.
![Click for copyable input](assets.fr/world-nuclear-reactors/In_77.png)
data = Transpose[{active, countries, annualproduction}];
data = DeleteMissing[data, 1, 2];
![Click for copyable input](assets.fr/world-nuclear-reactors/In_78.png)
data // Dimensions
![](assets.fr/world-nuclear-reactors/O_56.png)
Le nombre de réacteurs par pays.
![Click for copyable input](assets.fr/world-nuclear-reactors/In_79.png)
percountry = GroupBy[data, #1[[2]] &];
![Click for copyable input](assets.fr/world-nuclear-reactors/In_80.png)
numberpercountry = Map[Length, percountry];
![Click for copyable input](assets.fr/world-nuclear-reactors/In_81.png)
BarChart[Sort[numberpercountry], ChartLabels -> Automatic,
ChartStyle -> "DarkRainbow", BarOrigin -> Left, BarSpacing -> 1,
LabelingFunction -> (Placed[#1, After] &), ImageSize -> Large]
![](assets.fr/world-nuclear-reactors/O_57.png)
Le nombre de réacteurs correspond à l'énergie nucléaire totale produite par pays.
![Click for copyable input](assets.fr/world-nuclear-reactors/In_82.png)
energytotals = Map[Total[#[[All, 3]]] &, percountry];
![Click for copyable input](assets.fr/world-nuclear-reactors/In_83.png)
stats = {Min, Max, Mean, Median, Total};
TableForm[#[energytotals] & /@ stats, TableHeadings -> {stats}]
![](assets.fr/world-nuclear-reactors/O_58.png)
Les plus grands producteurs d'énergie nucléaire sont les États-Unis et la France.
![Click for copyable input](assets.fr/world-nuclear-reactors/In_84.png)
TakeLargest[energytotals, 2]
![](assets.fr/world-nuclear-reactors/O_59.png)
![](assets.fr/world-nuclear-reactors/O_60.png)
La carte est différente si l'on considère la production totale d'énergie par habitant. Utilisez CountryData pour accéder aux totaux de population pour chaque pays de la liste.
![Click for copyable input](assets.fr/world-nuclear-reactors/In_86.png)
populations =
AssociationThread[Keys[energytotals],
CountryData[#, "Population"] & /@ Keys[energytotals]];
Calculez l'énergie nucléaire par habitant.
![Click for copyable input](assets.fr/world-nuclear-reactors/In_87.png)
energypercapita = energytotals/populations;
![Click for copyable input](assets.fr/world-nuclear-reactors/In_88.png)
TableForm[#[energypercapita] & /@ stats, TableHeadings -> {stats}]
![](assets.fr/world-nuclear-reactors/O_61.png)
Sur la carte, vous pouvez voir que même si les États-Unis ont la plus grande production absolue d'énergie nucléaire, ils ne sont pas les plus grands par personne, puisque la France et la Suède sont en tête.
![Click for copyable input](assets.fr/world-nuclear-reactors/In_89.png)
TakeLargest[energypercapita, 2]
![](assets.fr/world-nuclear-reactors/O_62.png)
![](assets.fr/world-nuclear-reactors/O_63.png)