Weltweite Atomreaktoren
NuclearReactorData liefert Daten zu den bekannten Atomreaktoren auf der ganzen Welt. Manche befinden sich bereits außer Betrieb, so wie Tschernobyl. Für die Analyse der globalen Atomenergie-Ressourcen können Sie die derzeit aktiven Reaktoren auswählen.
![Click for copyable input](assets.de/world-nuclear-reactors/In_74.png)
reactors = NuclearReactorData[];
![Click for copyable input](assets.de/world-nuclear-reactors/In_75.png)
active = Keys@
Select[EntityValue["NuclearReactor", "Status",
"EntityAssociation"], # === "operational" &];
Extrahieren Sie die jährliche Energieproduktion und das Land des Standorts.
![Click for copyable input](assets.de/world-nuclear-reactors/In_76.png)
annualproduction =
NuclearReactorData[active, "AnnualEnergyProduction"];
countries = Map[First, NuclearReactorData[active, "Countries"]];
Erstellen Sie einen Datensatz und entfernen Sie die Datenpunkte, die fehlende Werte enthalten. Die Zahl der aktiven Reaktoren liegt bei über 400.
![Click for copyable input](assets.de/world-nuclear-reactors/In_77.png)
data = Transpose[{active, countries, annualproduction}];
data = DeleteMissing[data, 1, 2];
![Click for copyable input](assets.de/world-nuclear-reactors/In_78.png)
data // Dimensions
![](assets.de/world-nuclear-reactors/O_56.png)
Die Reaktoranzahl pro Land.
![Click for copyable input](assets.de/world-nuclear-reactors/In_79.png)
percountry = GroupBy[data, #1[[2]] &];
![Click for copyable input](assets.de/world-nuclear-reactors/In_80.png)
numberpercountry = Map[Length, percountry];
![Click for copyable input](assets.de/world-nuclear-reactors/In_81.png)
BarChart[Sort[numberpercountry], ChartLabels -> Automatic,
ChartStyle -> "DarkRainbow", BarOrigin -> Left, BarSpacing -> 1,
LabelingFunction -> (Placed[#1, After] &), ImageSize -> Large]
![](assets.de/world-nuclear-reactors/O_57.png)
Die Zahl der Reaktoren entspricht der Gesamtproduktion von Atomenergie pro Land.
![Click for copyable input](assets.de/world-nuclear-reactors/In_82.png)
energytotals = Map[Total[#[[All, 3]]] &, percountry];
![Click for copyable input](assets.de/world-nuclear-reactors/In_83.png)
stats = {Min, Max, Mean, Median, Total};
TableForm[#[energytotals] & /@ stats, TableHeadings -> {stats}]
![](assets.de/world-nuclear-reactors/O_58.png)
Die größten Produzenten von Atomenergie sind die Vereinigten Staaten und Frankreich.
![Click for copyable input](assets.de/world-nuclear-reactors/In_84.png)
TakeLargest[energytotals, 2]
![](assets.de/world-nuclear-reactors/O_59.png)
![](assets.de/world-nuclear-reactors/O_60.png)
Die Weltkarte sind anders aus, wenn man die Pro-Kopf-Gesamtenergieproduktion in betrachtet. Verwenden Sie CountryData, um die Einwohnerzahlen für jedes Land der Liste abzurufen.
![Click for copyable input](assets.de/world-nuclear-reactors/In_86.png)
populations =
AssociationThread[Keys[energytotals],
CountryData[#, "Population"] & /@ Keys[energytotals]];
Berechnen Sie die Atomenergie pro Kopf.
![Click for copyable input](assets.de/world-nuclear-reactors/In_87.png)
energypercapita = energytotals/populations;
![Click for copyable input](assets.de/world-nuclear-reactors/In_88.png)
TableForm[#[energypercapita] & /@ stats, TableHeadings -> {stats}]
![](assets.de/world-nuclear-reactors/O_61.png)
Auf der Karte sehen Sie, dass die USA nicht der größte Pro-Kopf-Atomstromproduzent sind, obwohl sie die meiste Atomenergie in absoluten Zahlen produzieren. Frankreich und Schweden führen die Pro-Kopf-Produktion an.
![Click for copyable input](assets.de/world-nuclear-reactors/In_89.png)
TakeLargest[energypercapita, 2]
![](assets.de/world-nuclear-reactors/O_62.png)
![](assets.de/world-nuclear-reactors/O_63.png)