Analise, visualize, e compare "superalimentos"

Superalimentos são alimentos que são muito ricos em um ou mais nutrientes. Este exemplo define um conjunto de superalimentos, em seguida, os compara com alimentos mais "tradicionais" usando dados de alimentos da Wolfram Knowledgebase. Finalmente, ele constrói um símbolo apropriada para alimentos que merecem ser chamados de "super".

Primeiro, defina uma lista de superalimentos que contenham os nutrientes pelo qual são conhecidos.

In[1]:=

superfoodsRawData = {{"greek yogurt", {"TotalProtein"}}, {"quinoa", \ {"TotalProtein"}}, {"blueberries", {"TotalFiber", "VitaminC"}}, {"kale", {"TotalFiber", "Calcium", "Iron"}}, {"chia", {"Magnesium", "Iron", "Calcium", "Potassium"}}, {"oatmeal", {"TotalFiber"}}, {"broccoli", \ {"TotalFiber", "VitaminC", "TotalFolate"}}, {"strawberries", {"VitaminC"}}, {"salmon", \ {"TotalProtein"}}, {"watermelon", {"TotalSugar", "VitaminA", "VitaminC", "TotalCalories"}}, {"lima beans", {"TotalFiber"}}, {"edamame", {"TotalFiber"}}, {"spinach", {"Calcium", "VitaminK"}}, {"pistachios", {"TotalProtein", "TotalFiber", "Potassium"}}, {"eggs", {"TotalProtein"}}, {"almonds", \ {"TotalFiber", "Potassium", "Calcium", "VitaminE", "Magnesium", "Iron"}}, {"pumpkin", {"BetaCarotene"}}, {"apples", \ {"TotalFiber", "TotalCalories"}}, {"lentils", {"TotalProtein", "Iron"}}};

Converta isto em Dataset para um cálculo mais fácil.

In[2]:=

superfoodsDatset = Dataset[<|"Food" -> #1, "Nutrients" -> #2|> & @@@ superfoodsRawData]

Out[2]=

Use Interpreter para obter entidades da Wolfram Language para os superalimentos.

In[3]:=

superfoodsDatset1 = superfoodsDatset[All, KeySort[Prepend[#, <| "FoodEntity" -> Interpreter["Food"][#Food]|>]] &];

Liste os nutrientes.

In[4]:=

Union @@ Normal[superfoodsDatset1[[All, "Nutrients"]]]

Out[4]=

Crie regras para converter os nutrientes fornecidos em suas propriedades adequadas.

In[5]:=

superfoodsDatset2 = superfoodsDatset1 /. AssociationMap[ EntityProperty["Food", "Relative" <> # <> "Content"] &, Union @@ Normal[superfoodsDatset1[[All, "Nutrients"]]]]

Out[5]=

Encontre os nutrientes mais comuns no Dataset.

In[6]:=

mostCommonProperties = superfoodsDatset2[Counts[Flatten[#]] &, "Nutrients"][TakeLargest[5]]

Out[6]=

Encontre superalimentos conhecidos por serem ricos em fibras e compare-os com cerca de 9.000 alimentos. Visualize como um histograma suavizado, onde a curva cinza mostra a função de densidade de probabilidade de teor de fibra para a maioria dos alimentos.

In[7]:=

fiberDataset = superfoodsDatset2[ Select[ContainsAny[#Nutrients, {EntityProperty["Food", "RelativeTotalFiberContent"]}] &], KeyDrop["Nutrients"]];

In[8]:=

foodTypeColors = <| Entity["FoodType", "Kale"] -> Directive[ColorData[97, 1]], Entity["FoodType", "Apple"] -> Directive[ColorData[97, 2]], Entity["FoodType", "Broccoli"] -> Directive[ColorData[97, 3]], Entity["FoodType", "Blueberry"] -> Directive[ColorData[97, 4]], Entity["FoodType", "Edamame"] -> Directive[ColorData[97, 5]], Entity["FoodType", "LimaBean"] -> Directive[ColorData[97, 6]], Entity["FoodType", "Oatmeal"] -> Directive[ColorData[97, 7]], Entity["FoodType", "PistachioNut"] -> Directive[ColorData[97, 8]], Entity["FoodType", "Almond"] -> Directive[ColorData[97, 9]] |>;

In[9]:=

property = EntityProperty["Food", "RelativeTotalFiberContent"];

In[10]:=

data = DeleteMissing[ EntityValue[EntityClass["Food", "DataSource" -> "USDA"], property]];

In[11]:=

fiberData = Flatten[data] /. {Quantity[a_, ___] :> a};

In[12]:=

epilog = MapIndexed[ With[{prop = #FoodEntity[property], head = Log, foodType = First[Cases[#FoodEntity, Entity["FoodType", _String], Infinity, 1]]}, Tooltip[ { foodTypeColors[foodType], AbsoluteThickness[3], Line[{{head[First[prop]], 0}, {head[First[prop]], 80}}] }, #Food] ] &, Reverse@SortBy[Normal[fiberDataset], Last]];

In[13]:=

SmoothHistogram[ fiberData, Automatic, "PDF", PlotRange -> {{.02, .4}, Full}, ScalingFunctions -> {"Log", None}, AspectRatio -> 1/3, Epilog -> epilog, PlotStyle -> GrayLevel[0, .01], Filling -> Axis, FillingStyle -> GrayLevel[0, .15], PlotTheme -> {"HeightGrid"}, PlotLegends -> LineLegend @@ Transpose[Reverse /@ List @@@ Normal[foodTypeColors]], PlotLabel -> "Fiber content of \"superfoods\"", FrameLabel -> {"Fiber (g/g)"} ]

Out[13]=

Faça o mesmo processo para superalimentos ricos em proteínas.

In[14]:=

proteinDataset = superfoodsDatset2[ Select[ContainsAny[#Nutrients, {EntityProperty["Food", "RelativeTotalProteinContent"]}] &], KeyDrop["Nutrients"]];

In[15]:=

foodTypeColors = <| Entity["FoodType", "Yogurt"] -> Directive[ColorData[97, 1]], Entity["FoodType", "Egg"] -> Directive[ColorData[97, 2]], Entity["FoodType", "Quinoa"] -> Directive[ColorData[97, 3]], Entity["FoodType", "PistachioNut"] -> Directive[ColorData[97, 4]], Entity["FoodType", "Salmon"] -> Directive[ColorData[97, 5]], Entity["FoodType", "Lentil"] -> Directive[ColorData[97, 6]] |>;

In[16]:=

property = EntityProperty["Food", "RelativeTotalProteinContent"];

In[17]:=

dataset = proteinDataset;

In[18]:=

data = DeleteMissing[ EntityValue[EntityClass["Food", "DataSource" -> "USDA"], property]];

In[19]:=

proteinData = Flatten[data] /. {Quantity[a_, ___] :> a};

In[20]:=

epilog = MapIndexed[ With[{prop = #FoodEntity[property], head = Log, foodType = First[Cases[#FoodEntity, Entity["FoodType", _String], Infinity, 1]]}, Tooltip[ { Replace[foodTypeColors[foodType], _Missing -> Black], AbsoluteThickness[3], Line[{{head[First[prop]], 0}, {head[First[prop]], 80000}}] }, #Food] ] &, Reverse@SortBy[Normal[dataset], Last]];

In[21]:=

SmoothHistogram[ proteinData, Automatic, "PDF", PlotRange -> {{.02, .4}, Full}, ScalingFunctions -> {"Log", None}, Epilog -> epilog, AspectRatio -> 1/3, PlotStyle -> GrayLevel[0, .01], Filling -> Axis, FillingStyle -> GrayLevel[0, .15], PlotLegends -> LineLegend @@ Transpose[Reverse /@ List @@@ Normal[foodTypeColors]], PlotTheme -> {"HeightGrid"}, PlotLabel -> "Protein content of \"superfoods\"", FrameLabel -> {"Protein (g/g)"} ]

Out[21]=

Crie um símbolo para os superalimentos, começando com um conjunto de imagens de superalimentos.

In[22]:=

GraphicsGrid[ Partition[ ims = EntityValue[ Cases[superfoodsDatset2[All, "FoodEntity"] // Normal, Entity["FoodType", _], Infinity], "Image"], UpTo[5]]]

Out[22]=

Como o fundo, use um formato semelhante a um símbolo de um super herói bem conhecido.

In[23]:=

Entity["Lamina", "SupermanInsigniaLamina"]["Image"] // ImageCrop

Out[23]=

Use um pouco de processamento de imagem simples para convertê-lo em um fundo.

In[24]:=

background = ColorNegate[ Binarize[Entity["Lamina", "SupermanInsigniaLamina"]["Image"], .99]]

Out[24]=

Crie uma "nuvem de palavras" de superalimentos.

In[25]:=

wc = WordCloud[(RandomReal[{0.6, 1.2}] -> #) & /@ ims, background]

Out[25]=

Combine a nunvem de palavras com o fundo.

In[26]:=

ImageMultiply[{ColorReplace[background, Black -> LightGray], wc}]

Out[26]=