Pinturas e artistas do Museu de Arte Moderna
O Museu de Arte Moderna (MoMA) mantem um conjunto de dados públicos em https://github.com/MuseumofModernArt/collection contendo informações detalhadas sobre suas coleções. Aqui, você pode fazer uso de um banco de dados de entidades personalizado com esses dados para estudar as dimensões de pinturas do MoMA, assim como investigar a longevidade de seus artistas.
Primeiro, carregue o banco de entidades já existente em ResourceObject.
![Click for copyable input](assets.pt-br/museum-of-modern-art-paintings-and-artists/In_168.png)
momaStore = ResourceData[
ResourceObject[
Association[
"Name" -> "Museum of Modern Art Holdings and Artists",
"UUID" -> "38f47cc0-667d-4988-8ebe-6c1bef23fdc6",
"ResourceType" -> "DataResource", "Version" -> "1.0.0",
"Description" -> "Holdings and artists of The Museum of Modern \
Art", "ContentSize" -> Association["EntityStore" -> 0],
"ContentElements" -> {"EntityStore"}]]]
![](assets.pt-br/museum-of-modern-art-paintings-and-artists/O_116.png)
Registre o banco de dados para esta sessão.
![Click for copyable input](assets.pt-br/museum-of-modern-art-paintings-and-artists/In_169.png)
PrependTo[$EntityStores, momaStore];
Obtenha uma lista de propriedades de obras de arte a partir do banco de dados de entidades usando o tipo de entidade"MoMAHolding".
![Click for copyable input](assets.pt-br/museum-of-modern-art-paintings-and-artists/In_170.png)
EntityProperties["MoMAHolding"]
![](assets.pt-br/museum-of-modern-art-paintings-and-artists/O_117.png)
Liste valores de propriedade representativos para uma determinada peça.
![Click for copyable input](assets.pt-br/museum-of-modern-art-paintings-and-artists/In_171.png)
DeleteMissing[
EntityValue[Entity["MoMAHolding", "79802"],
"PropertyAssociation" ]] // Take[#, 15] &
![](assets.pt-br/museum-of-modern-art-paintings-and-artists/O_118.png)
Faça um histograma com as datas de conclusão de todas as obras no MoMA.
![Click for copyable input](assets.pt-br/museum-of-modern-art-paintings-and-artists/In_172.png)
DateHistogram[
DeleteMissing[EntityValue["MoMAHolding", "CompletionDate"]]]
![](assets.pt-br/museum-of-modern-art-paintings-and-artists/O_119.png)
Registre os tipos de obras na coleção.
![Click for copyable input](assets.pt-br/museum-of-modern-art-paintings-and-artists/In_173.png)
TextGrid[SortBy[
Tally[EntityValue["MoMAHolding",
EntityProperty["MoMAHolding", "Classification"]]], Last] //
Reverse, Dividers -> All,
Background -> {Automatic, {{LightBlue, None}}},
Alignment -> {{Left, Decimal}, Automatic}]
![](assets.pt-br/museum-of-modern-art-paintings-and-artists/O_120.png)
Use classes de entidade definidas implicitamente para extrair pinturas do MoMA.
![Click for copyable input](assets.pt-br/museum-of-modern-art-paintings-and-artists/In_174.png)
paintings =
EntityClass[
"MoMAHolding", {EntityProperty["MoMAHolding", "Classification"] ->
"Painting"}];
Faça um histograma das proporções e áreas das pinturas. Nos intervalos padrão de largura, a distribuição de proporções de aspecto parece ser trimodal.
![Click for copyable input](assets.pt-br/museum-of-modern-art-paintings-and-artists/In_175.png)
Table[Histogram[EntityValue[paintings, prop],
PlotLabel ->
prop], {prop, {EntityProperty["MoMAHolding", "AspectRatio"],
EntityProperty["MoMAHolding", "Area"]}}]
![](assets.pt-br/museum-of-modern-art-paintings-and-artists/O_121.png)
Agora obtenha uma lista de propriedades associadas com artistas usando o tipo de entidade "MoMAArtist".
![Click for copyable input](assets.pt-br/museum-of-modern-art-paintings-and-artists/In_176.png)
EntityProperties["MoMAArtist"]
![](assets.pt-br/museum-of-modern-art-paintings-and-artists/O_122.png)
Veja as propriedades para o artista Vincent van Gogh como uma "PropertyAssociation".
![Click for copyable input](assets.pt-br/museum-of-modern-art-paintings-and-artists/In_177.png)
EntityValue[
Entity["MoMAArtist", "Vincent van Gogh"], "PropertyAssociation"]
![](assets.pt-br/museum-of-modern-art-paintings-and-artists/O_123.png)
Visualize a distribuição das contagens de trabalho no MoMA para todos os artistas.
![Click for copyable input](assets.pt-br/museum-of-modern-art-paintings-and-artists/In_178.png)
Histogram[
Length /@ EntityValue["MoMAArtist", "MoMAPieces"], {"Log", 20}]
![](assets.pt-br/museum-of-modern-art-paintings-and-artists/O_124.png)
Explore a duração média de vida dos artistas falecidos, selecionando primeiro os artistas que as datas de nascimento e morte definidas, em seguida, depois calcule a diferença de data entre ambas, e finalmente o calcule a média.
![Click for copyable input](assets.pt-br/museum-of-modern-art-paintings-and-artists/In_179.png)
deceasedArtists =
Select[EntityList["MoMAArtist"],
AllTrue[# /@ {"BirthDate", "DeathDate"}, DateObjectQ] &];
![Click for copyable input](assets.pt-br/museum-of-modern-art-paintings-and-artists/In_180.png)
Mean[DateDifference[#["BirthDate"], #["DeathDate"], "Year"] & /@
deceasedArtists] // N
![](assets.pt-br/museum-of-modern-art-paintings-and-artists/O_125.png)
Crie colagens de algumas peças MoMA selecionadas aleatoriamente de cada década do século XX.
![](assets.pt-br/museum-of-modern-art-paintings-and-artists/O_126.png)