Visualize Eigenfunctions
Define a 3D Laplacian operator.
In[1]:=
![Click for copyable input](assets.en/visualize-eigenfunctions/In_35.png)
\[ScriptCapitalL] = -Laplacian[u[x, y, z], {x, y, z}];
Specify homogeneous Dirichlet boundary conditions.
In[2]:=
![Click for copyable input](assets.en/visualize-eigenfunctions/In_36.png)
\[ScriptCapitalB] = DirichletCondition[u[x, y, z] == 0, True];
Find the smallest eigenvalues and eigenfunctions in a ball.
In[3]:=
![Click for copyable input](assets.en/visualize-eigenfunctions/In_37.png)
\[CapitalOmega] = Ball[{0, 0, 0}, 2];
{vals, funs} =
DEigensystem[{\[ScriptCapitalL], \[ScriptCapitalB]},
u[x, y, z], {x, y, z} \[Element] \[CapitalOmega], 2];
In[4]:=
![Click for copyable input](assets.en/visualize-eigenfunctions/In_38.png)
funs
Out[4]=
![](assets.en/visualize-eigenfunctions/O_16.png)
Plot each eigenfunction using a 3D density plot.
In[5]:=
![Click for copyable input](assets.en/visualize-eigenfunctions/In_39.png)
Table[DensityPlot3D[
Evaluate[N[f]], {x, y, z} \[Element] \[CapitalOmega],
PlotTheme -> "NoAxes", PlotLegends -> Placed[Automatic, Below]], {f,
funs}]
Out[5]=
![](assets.en/visualize-eigenfunctions/O_17.png)
Use coordinate planes to plot the density.
In[6]:=
![Click for copyable input](assets.en/visualize-eigenfunctions/In_40.png)
Table[SliceDensityPlot3D[
Evaluate[N[f]], {x, y, z} \[Element] \[CapitalOmega],
PlotLegends -> Placed[Automatic, Below]], {f, funs}]
Out[6]=
![](assets.en/visualize-eigenfunctions/O_18.png)