求反应网络的化学平衡 

化学反应系统拥有的平衡通常可作为多项式系统方程进行直接建模. 该类问题由守恒和反应方程定义. 以下范例来自燃烧化学，是模拟了如汽车发动机的燃烧室中燃料燃烧的模型. 目的是为了找出在不同阶段燃烧室中的化学成分和混合物. 研究的反应系统由 、、、、、、 给定

引入一个变量作为每种成分的量. 由于 不自身产生，在此 被视为一种成分.

引入一个变量作为每种化合物的量.

In[1]:=

X vars = {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[ x, 4], Subscript[x, 5], Subscript[x, 6], Subscript[x, 7], Subscript[x, 8], Subscript[x, 9], Subscript[x, 10]};

如果假设为一个封闭的化学系统，且数量守恒，将导出以化学和代数符号表示的守恒方程组

In[2]:=

X conservation = {Subscript[x, 2] + 2 Subscript[x, 6] + Subscript[x, 9] + 2 Subscript[x, 10] == Subscript[T, H], Subscript[x, 3] + Subscript[x, 8] == Subscript[T, CO], Subscript[x, 1] + Subscript[x, 3] + 2 Subscript[x, 5] + 2 Subscript[x, 8] + Subscript[x, 9] + Subscript[x, 10] == Subscript[T, O], Subscript[x, 4] + 2 Subscript[x, 7] == Subscript[T, N]};

给出平衡方程组.

In[3]:=

X equilibrium = {Subscript[x, 5] == Subscript[R, 1] Subscript[x, 1]^2, Subscript[x, 6] == Subscript[R, 2] Subscript[x, 2]^2, Subscript[x, 7] == Subscript[R, 3] Subscript[x, 4]^2, Subscript[x, 8] == Subscript[R, 4] Subscript[x, 1] Subscript[x, 3], Subscript[x, 9] == Subscript[R, 5] Subscript[x, 1] Subscript[x, 2], Subscript[x, 10] == Subscript[R, 6] Subscript[x, 1] Subscript[x, 2]^2};

给出参数值.

In[4]:=

X pars = {Subscript[T, O] -> 5 10^-5, Subscript[T, CO] -> 3 10^-5, Subscript[T, H] -> 1 10^-5, Subscript[T, N] -> 1 10^-5, Subscript[R, 1] -> 24.528, Subscript[R, 2] -> 22.206, Subscript[R, 3] -> 47.970, Subscript[R, 4] -> 24.942, Subscript[R, 5] -> 22.120, Subscript[R, 6] -> 46.989};

在实数域求解，并仅选择非负解.

In[5]:=

X rsols = NSolve[Join[conservation, equilibrium] /. pars, vars, Reals];

In[6]:=

X Thread[vars -> SelectFirst[vars /. rsols, VectorQ[#, NonNegative] &]]

Out[6]=

计算更精确的解.

In[7]:=

X rsols = NSolve[ SetPrecision[Join[conservation, equilibrium] /. pars, 20], vars, Reals, WorkingPrecision -> 20];

In[8]:=

X Thread[vars -> SelectFirst[vars /. rsols, VectorQ[#, NonNegative] &]]

Out[8]=