Antisymmetric and Orthogonal Matrices 

If is an antisymmetric matrix and is a vector obeying the differential equation , then has constant magnitude. Consider first a constant matrix.

In[1]:=

X aSimple[t_] = {{0, 1, 2}, {-1, 0, 3}, {-2, -3, 0}};

In[2]:=

X AntisymmetricMatrixQ[aSimple[t]]

Out[2]=

The solution to the differential equation can be written down using MatrixExp.

In[3]:=

X u[t_] = MatrixExp[aSimple[t] t];

In[4]:=

X vSimple[t_] := u[t] . {vx, vy, vz};

Verify that is indeed a solution.

In[5]:=

X vSimple'[t] == aSimple[t].vSimple[t] // Simplify

Out[5]=

The matrix used to define the solution is orthogonal.

In[6]:=

X OrthogonalMatrixQ[u[t]]

Out[6]=

Solutions to constant coefficient equations trace repeating circles on the sphere.

In[7]:=

X Block[{vx = 0, vy = 0, vz = 1}, Show[ParametricPlot3D[vSimple[t], {t, 0, 10}, Lighting -> "Neutral", ColorFunction -> (ColorData["Rainbow"][#4] &)], Graphics3D[{Opacity[.5], Sphere[]}], PlotRange -> All, ImageSize -> Medium]]

Out[7]=

Solutions for a nonconstant coefficient matrix might require numerical solutions.

In[8]:=

X aComplex[t_] := {{0, -t + Sin[t], -Cos[t/2]}, {t - Sin[t], 0, t Cos[t]}, {Cos[t/2], -t Cos[t], 0}}

In[9]:=

X AntisymmetricMatrixQ[aComplex[t]]

Out[9]=

While motion is still restricted to a sphere, more interesting patterns are now possible.

In[10]:=

X vComplex = NDSolveValue[{v'[t] == aComplex[t].v[t], v[0] == {1, 0, 0}}, v, {t, 0, 10}];

In[11]:=

X Show[ParametricPlot3D[vComplex[t], {t, 0, 10}, Lighting -> "Neutral", ColorFunction -> (ColorData["Rainbow"][#4] &)], Graphics3D[{Opacity[.5], Sphere[]}], PlotRange -> All, ImageSize -> Medium]

Out[11]=