シャンペーンまで運転する
アメリカの300の都市から,イリノイ州シャンペーンにあるWolfram Researchの本社までの経路を描画する.
In[1]:=
![Click for copyable input](assets.ja/drive-to-champaign/In_46.png)
champaign = Entity["City", {"Champaign", "Illinois", "UnitedStates"}]
Out[1]=
![](assets.ja/drive-to-champaign/O_32.png)
In[2]:=
![Click for copyable input](assets.ja/drive-to-champaign/In_47.png)
us = Entity["Country", "UnitedStates"]
Out[2]=
![](assets.ja/drive-to-champaign/O_33.png)
アメリカの10万人以上の都市のリストを取る.
In[3]:=
![Click for copyable input](assets.ja/drive-to-champaign/In_48.png)
Length[cities = CityData[{Large, "UnitedStates"}]]
Out[3]=
![](assets.ja/drive-to-champaign/O_34.png)
シャンペーンまでの経路を計算する.
In[4]:=
![Click for copyable input](assets.ja/drive-to-champaign/In_49.png)
roads = Quiet@TravelDirections[{#, champaign}, "TravelPath"] & /@
cities;
ホノルルからシャンペーンまで等,不可能なものは除外する.
In[5]:=
![Click for copyable input](assets.ja/drive-to-champaign/In_50.png)
Length[roads = Cases[roads, _GeoPath]]
Out[5]=
![](assets.ja/drive-to-champaign/O_35.png)
地図を描く.
In[6]:=
![Click for copyable input](assets.ja/drive-to-champaign/In_51.png)
GeoGraphics[{
GeoStyling[White], Polygon[us],
Red, Opacity[.1], roads,
Black, Opacity[0.6], Point[cities],
Blue, Opacity[1], PointSize[Large], Point[champaign]
}, GeoBackground -> LightBlue, ImageSize -> 600,
GeoRange -> us] // Rasterize
Out[6]=
![](assets.ja/drive-to-champaign/O_36.png)