Projected Grid of Latitude and Longitude Lines
This function draws the full grid of parallels and meridians (in red and blue, respectively) after being projected with a geo projection.
In[1]:=
![Click for copyable input](assets.en/projected-grid-of-latitude-and-longitude-lines/In_29.png)
graticule[proj_] :=
With[{centering = {0, 0, 1.5},
diff = Quantity[10, "AngularDegrees"]},
Framed[Labeled[
GeoGraphics[GeoRange -> "World",
GeoProjection -> {proj, "Centering" -> centering},
GeoGridLines -> diff, GeoGridLinesStyle -> {Red, Blue},
GeoBackground -> None, PlotRangePadding -> Scaled[0.1]], proj]]
]
These are three examples.
In[2]:=
![Click for copyable input](assets.en/projected-grid-of-latitude-and-longitude-lines/In_30.png)
graticule["Armadillo"]
Out[2]=
![](assets.en/projected-grid-of-latitude-and-longitude-lines/O_18.png)
In[3]:=
![Click for copyable input](assets.en/projected-grid-of-latitude-and-longitude-lines/In_31.png)
graticule["AmericanPolyconic"]
Out[3]=
![](assets.en/projected-grid-of-latitude-and-longitude-lines/O_19.png)
In[4]:=
![Click for copyable input](assets.en/projected-grid-of-latitude-and-longitude-lines/In_32.png)
graticule["Bonne"]
Out[4]=
![](assets.en/projected-grid-of-latitude-and-longitude-lines/O_20.png)
Compute the latitude-longitude grids for all 151 projections with a spherical reference model.
In[5]:=
![Click for copyable input](assets.en/projected-grid-of-latitude-and-longitude-lines/In_33.png)
plots = graticule /@ GeoProjectionData["Spherical"];
Rasterize them using a small enough image size.
In[6]:=
![Click for copyable input](assets.en/projected-grid-of-latitude-and-longitude-lines/In_34.png)
images = Rasterize[#, ImageSize -> 200] & /@ plots;
Construct an image collage.
In[7]:=
![Click for copyable input](assets.en/projected-grid-of-latitude-and-longitude-lines/In_35.png)
ImageCollage[images]
Out[7]=
![](assets.en/projected-grid-of-latitude-and-longitude-lines/O_21.png)