Grade projetada de linhas de latitude e longitude
Esta função traça a grade completa de paralelos e meridianos (em vermelho e azul, respectivamente) depois de serem projetadas com uma projeção geográfica.
In[1]:=
![Click for copyable input](assets.pt-br/projected-grid-of-latitude-and-longitude-lines/In_29.png)
graticule[proj_] :=
With[{centering = {0, 0, 1.5},
diff = Quantity[10, "AngularDegrees"]},
Framed[Labeled[
GeoGraphics[GeoRange -> "World",
GeoProjection -> {proj, "Centering" -> centering},
GeoGridLines -> diff, GeoGridLinesStyle -> {Red, Blue},
GeoBackground -> None, PlotRangePadding -> Scaled[0.1]], proj]]
]
Esses sãpo três exemplos.
In[2]:=
![Click for copyable input](assets.pt-br/projected-grid-of-latitude-and-longitude-lines/In_30.png)
graticule["Armadillo"]
Out[2]=
![](assets.pt-br/projected-grid-of-latitude-and-longitude-lines/O_18.png)
In[3]:=
![Click for copyable input](assets.pt-br/projected-grid-of-latitude-and-longitude-lines/In_31.png)
graticule["AmericanPolyconic"]
Out[3]=
![](assets.pt-br/projected-grid-of-latitude-and-longitude-lines/O_19.png)
In[4]:=
![Click for copyable input](assets.pt-br/projected-grid-of-latitude-and-longitude-lines/In_32.png)
graticule["Bonne"]
Out[4]=
![](assets.pt-br/projected-grid-of-latitude-and-longitude-lines/O_20.png)
Calcule as grades de latitude e longitude para todas as 151 projeções com um modelo de referência esférico.
In[5]:=
![Click for copyable input](assets.pt-br/projected-grid-of-latitude-and-longitude-lines/In_33.png)
plots = graticule /@ GeoProjectionData["Spherical"];
Rasterize-os usando um tamanho da imagem pequena o suficiente.
In[6]:=
![Click for copyable input](assets.pt-br/projected-grid-of-latitude-and-longitude-lines/In_34.png)
images = Rasterize[#, ImageSize -> 200] & /@ plots;
Faça uma colagem de imagens.
In[7]:=
![Click for copyable input](assets.pt-br/projected-grid-of-latitude-and-longitude-lines/In_35.png)
ImageCollage[images]
Out[7]=
![](assets.pt-br/projected-grid-of-latitude-and-longitude-lines/O_21.png)