Спроецированная сетка линий широты и долготы
Данная функция чертит полную сетку параллелей и меридианов (красным и синим цветом соответственно) после проецирования при помощи геопроекции.
In[1]:=
![Click for copyable input](assets.ru/projected-grid-of-latitude-and-longitude-lines/In_29.png)
graticule[proj_] :=
With[{centering = {0, 0, 1.5},
diff = Quantity[10, "AngularDegrees"]},
Framed[Labeled[
GeoGraphics[GeoRange -> "World",
GeoProjection -> {proj, "Centering" -> centering},
GeoGridLines -> diff, GeoGridLinesStyle -> {Red, Blue},
GeoBackground -> None, PlotRangePadding -> Scaled[0.1]], proj]]
]
Далее представлены три примера.
In[2]:=
![Click for copyable input](assets.ru/projected-grid-of-latitude-and-longitude-lines/In_30.png)
graticule["Armadillo"]
Out[2]=
![](assets.ru/projected-grid-of-latitude-and-longitude-lines/O_18.png)
In[3]:=
![Click for copyable input](assets.ru/projected-grid-of-latitude-and-longitude-lines/In_31.png)
graticule["AmericanPolyconic"]
Out[3]=
![](assets.ru/projected-grid-of-latitude-and-longitude-lines/O_19.png)
In[4]:=
![Click for copyable input](assets.ru/projected-grid-of-latitude-and-longitude-lines/In_32.png)
graticule["Bonne"]
Out[4]=
![](assets.ru/projected-grid-of-latitude-and-longitude-lines/O_20.png)
Рассчитайте сетки широты-долготы для каждой из 151 проекции со сферической референц-моделью.
In[5]:=
![Click for copyable input](assets.ru/projected-grid-of-latitude-and-longitude-lines/In_33.png)
plots = graticule /@ GeoProjectionData["Spherical"];
Растрируйте их, используя изображение достаточно маленького размера.
In[6]:=
![Click for copyable input](assets.ru/projected-grid-of-latitude-and-longitude-lines/In_34.png)
images = Rasterize[#, ImageSize -> 200] & /@ plots;
Создайте коллаж изображений.
In[7]:=
![Click for copyable input](assets.ru/projected-grid-of-latitude-and-longitude-lines/In_35.png)
ImageCollage[images]
Out[7]=
![](assets.ru/projected-grid-of-latitude-and-longitude-lines/O_21.png)