Grille projetée de lignes de latitude et longitude
Cette fonction trace la grille complète des parallèles et méridiens (en rouge et bleu, respectivement) après avoir été projetée avec une projection géographique.
In[1]:=
![Click for copyable input](assets.fr/projected-grid-of-latitude-and-longitude-lines/In_29.png)
graticule[proj_] :=
With[{centering = {0, 0, 1.5},
diff = Quantity[10, "AngularDegrees"]},
Framed[Labeled[
GeoGraphics[GeoRange -> "World",
GeoProjection -> {proj, "Centering" -> centering},
GeoGridLines -> diff, GeoGridLinesStyle -> {Red, Blue},
GeoBackground -> None, PlotRangePadding -> Scaled[0.1]], proj]]
]
Voici trois exemples.
In[2]:=
![Click for copyable input](assets.fr/projected-grid-of-latitude-and-longitude-lines/In_30.png)
graticule["Armadillo"]
Out[2]=
![](assets.fr/projected-grid-of-latitude-and-longitude-lines/O_18.png)
In[3]:=
![Click for copyable input](assets.fr/projected-grid-of-latitude-and-longitude-lines/In_31.png)
graticule["AmericanPolyconic"]
Out[3]=
![](assets.fr/projected-grid-of-latitude-and-longitude-lines/O_19.png)
In[4]:=
![Click for copyable input](assets.fr/projected-grid-of-latitude-and-longitude-lines/In_32.png)
graticule["Bonne"]
Out[4]=
![](assets.fr/projected-grid-of-latitude-and-longitude-lines/O_20.png)
Calculez les grilles de latitude-longitude pour les 151 projections avec un modèle de référence sphérique.
In[5]:=
![Click for copyable input](assets.fr/projected-grid-of-latitude-and-longitude-lines/In_33.png)
plots = graticule /@ GeoProjectionData["Spherical"];
Pixelisez-les en utilisant une taille d'image assez petite.
In[6]:=
![Click for copyable input](assets.fr/projected-grid-of-latitude-and-longitude-lines/In_34.png)
images = Rasterize[#, ImageSize -> 200] & /@ plots;
Créez un collage d'image.
In[7]:=
![Click for copyable input](assets.fr/projected-grid-of-latitude-and-longitude-lines/In_35.png)
ImageCollage[images]
Out[7]=
![](assets.fr/projected-grid-of-latitude-and-longitude-lines/O_21.png)