Поездка на машине в Шампейн
Начертите дороги от 300 самых больших городов в США до штаб-квартиры Wolfram Research в Шампейн, штат Иллинойс.
In[1]:=
![Click for copyable input](assets.ru/drive-to-champaign/In_46.png)
champaign = Entity["City", {"Champaign", "Illinois", "UnitedStates"}]
Out[1]=
![](assets.ru/drive-to-champaign/O_32.png)
In[2]:=
![Click for copyable input](assets.ru/drive-to-champaign/In_47.png)
us = Entity["Country", "UnitedStates"]
Out[2]=
![](assets.ru/drive-to-champaign/O_33.png)
Далее представлен список самых больших городов в США.
In[3]:=
![Click for copyable input](assets.ru/drive-to-champaign/In_48.png)
Length[cities = CityData[{Large, "UnitedStates"}]]
Out[3]=
![](assets.ru/drive-to-champaign/O_34.png)
Рассчитайте маршруты до г. Шампейн.
In[4]:=
![Click for copyable input](assets.ru/drive-to-champaign/In_49.png)
roads = Quiet@TravelDirections[{#, champaign}, "TravelPath"] & /@
cities;
Исключите несколько не удовлетворяющих требованиям результатов, таких как маршрут Гонолулу-Шампейн.
In[5]:=
![Click for copyable input](assets.ru/drive-to-champaign/In_50.png)
Length[roads = Cases[roads, _GeoPath]]
Out[5]=
![](assets.ru/drive-to-champaign/O_35.png)
Начертите карту.
In[6]:=
![Click for copyable input](assets.ru/drive-to-champaign/In_51.png)
GeoGraphics[{
GeoStyling[White], Polygon[us],
Red, Opacity[.1], roads,
Black, Opacity[0.6], Point[cities],
Blue, Opacity[1], PointSize[Large], Point[champaign]
}, GeoBackground -> LightBlue, ImageSize -> 600,
GeoRange -> us] // Rasterize
Out[6]=
![](assets.ru/drive-to-champaign/O_36.png)