Stichproben aus einem Poisson-Punktprozess
Ein Poisson-Punktprozess ist eine multidimensionale Verallgemeinerung des eindimensionalen Poisson-Prozesses. Ein homogener Poisson-Punktprozess in geometrischen Regionen kann mittels RandomPoint erzeugt werden.
Erstellen Sie das Polygon eines Landes.
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_56.png)
region = DiscretizeGraphics[CountryData["Mexico", "Polygon"],
ImageSize -> Medium]
![](assets.de/sample-from-a-poisson-point-process/O_46.png)
Bestimmen Sie eine Funktion zur Stichprobennahme des Poisson-Punktprozesses mit drei Argumenten: Region, Intensität und Anzahl der Realisierungen.
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_57.png)
ppp[region_, intensity_, n_] := Module[{nlist, pts},
nlist =
RandomVariate[PoissonDistribution[intensity RegionMeasure[region]],
n];
pts = RandomPoint[region, Total[nlist]];
nlist = Accumulate[nlist];
nlist = Transpose[{Prepend[Most[nlist] + 1, 1], nlist}];
Table[Take[pts, ind], {ind, nlist}]
]
Generieren Sie eine Realisierung des Poisson-Punkprozesses im Länder-Polygon mit Intensität 0,5 und visualisieren Sie ihn mit Graphics.
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_58.png)
intensity = 0.5;
sample = ppp[region, intensity, 1];
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_59.png)
Show[region, Graphics[{Black, Point @@ sample}]]
![](assets.de/sample-from-a-poisson-point-process/O_47.png)
Generieren Sie 104 Stichproben desselben Prozesses. Die Gesamtzahl der Punkte in jeder Stichprobe erfüllt die PoissonDistribution, wobei der Mittelwert gleich zur Intensität Mal Flächeninhalt der Region ist.
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_60.png)
samples = ppp[region, intensity, 10^4];
counts = Length /@ samples;
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_61.png)
htd = PearsonChiSquareTest[counts,
PoissonDistribution[intensity RegionMeasure[region]],
"HypothesisTestData"];
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_62.png)
htd["TestDataTable"]
![](assets.de/sample-from-a-poisson-point-process/O_48.png)
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_63.png)
htd["TestConclusion"]
![](assets.de/sample-from-a-poisson-point-process/O_49.png)
Generieren Sie 104 Stichproben desselben Prozesses. Die Gesamtzahl der Punkte in jeder Stichprobe erfüllt die PoissonDistribution, wobei der Mittelwert gleich zur Intensität Mal Flächeninhalt der Region ist.
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_64.png)
disk1 = Disk[{-107, 28}, 1.5];
Show[region, Graphics[{Red, disk1}]]
![](assets.de/sample-from-a-poisson-point-process/O_50.png)
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_65.png)
memberfun1 = RegionMember[disk1];
counts1 = Table[Total[Boole[memberfun1[pts]]], {pts, samples}];
Prüfen Sie mit dem PearsonChiSquareTest die Anzahl der Zählungen mit einer Poisson-Verteilung.
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_66.png)
htd = PearsonChiSquareTest[counts1,
PoissonDistribution[intensity RegionMeasure[disk1]],
"HypothesisTestData"];
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_67.png)
htd["TestDataTable"]
![](assets.de/sample-from-a-poisson-point-process/O_51.png)
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_68.png)
htd["TestConclusion"]
![](assets.de/sample-from-a-poisson-point-process/O_52.png)
Die Zahl der Punkte in jeder beliebigen disjunkten Unterregion ist unabhängig. In diesem Beispiel wird die Anzahl der Punkte in zwei disjunkten Scheiben gezählt und der SpearmanRankTest durchgeführt.
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_69.png)
disk2 = Disk[{-100, 20}, 1.3];
Show[region, Graphics[{Red, disk1, Blue, disk2}]]
![](assets.de/sample-from-a-poisson-point-process/O_53.png)
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_70.png)
memberfun2 = RegionMember[disk2];
counts2 = Table[Total[Boole[memberfun2[pts]]], {pts, samples}];
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_71.png)
htd = SpearmanRankTest[counts1, counts2, "HypothesisTestData"];
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_72.png)
htd["TestDataTable"]
![](assets.de/sample-from-a-poisson-point-process/O_54.png)
![Click for copyable input](assets.de/sample-from-a-poisson-point-process/In_73.png)
htd["TestConclusion"]
![](assets.de/sample-from-a-poisson-point-process/O_55.png)