Route durch alle Hauptstädte der zusammenhängenden US-Staaten
Ermitteln Sie die Liste der Hauptstädte der 48 zusammenhängenden US-Staaten.
In[1]:=
![Click for copyable input](assets.de/travel-all-capitals-of-the-conterminous-us-states/In_49.png)
capitals =
EntityValue[
EntityClass["AdministrativeDivision", "ContinentalUSStates"],
"CapitalCity"]
Out[1]=
![](assets.de/travel-all-capitals-of-the-conterminous-us-states/O_38.png)
Downloaden Sie die jeweiligen GeoPosition-Koordinaten.
In[2]:=
![Click for copyable input](assets.de/travel-all-capitals-of-the-conterminous-us-states/In_50.png)
GeoPosition[capitals]
Out[2]=
![](assets.de/travel-all-capitals-of-the-conterminous-us-states/O_39.png)
Berechnen Sie die Reihenfolge, in der die Städte besucht werden sollen, um die geodätische Gesamtdistanz zu minimieren.
In[3]:=
![Click for copyable input](assets.de/travel-all-capitals-of-the-conterminous-us-states/In_51.png)
GeoPosition[capitals];
{d, perm} = FindShortestTour[%]
Out[3]=
![](assets.de/travel-all-capitals-of-the-conterminous-us-states/O_40.png)
Stellen Sie diesen Pfad auf einer Karte dar.
In[4]:=
![Click for copyable input](assets.de/travel-all-capitals-of-the-conterminous-us-states/In_52.png)
GeoGraphics[{GeoPath[capitals[[perm]]], Red, PointSize[Medium],
Point[capitals]}]
Out[4]=
![](assets.de/travel-all-capitals-of-the-conterminous-us-states/O_41.png)
Berechnen Sie nun die entsprechende Fahrtroute, um in dieser Reihenfolge durch diese Städte zu fahren.
In[5]:=
![Click for copyable input](assets.de/travel-all-capitals-of-the-conterminous-us-states/In_53.png)
td = TravelDirections[capitals[[perm]]];
Stellen Sie den resultierenden Pfad auf einer Karte dar.
In[6]:=
![Click for copyable input](assets.de/travel-all-capitals-of-the-conterminous-us-states/In_54.png)
GeoGraphics[{td["TravelPath"], Red, PointSize[Medium],
Point[capitals]}]
Out[6]=
![](assets.de/travel-all-capitals-of-the-conterminous-us-states/O_42.png)
Die zurückzulegende Gesamtdistanz ist:
In[7]:=
![Click for copyable input](assets.de/travel-all-capitals-of-the-conterminous-us-states/In_55.png)
td["TravelDistance"]
Out[7]=
![](assets.de/travel-all-capitals-of-the-conterminous-us-states/O_43.png)
Vergleichen Sie diese mit der geodätischen Entfernung.
In[8]:=
![Click for copyable input](assets.de/travel-all-capitals-of-the-conterminous-us-states/In_56.png)
d
Out[8]=
![](assets.de/travel-all-capitals-of-the-conterminous-us-states/O_44.png)