분류 성능의 측정
MNIST의 육필 숫자 데이터베이스에서 훈련된 숫자 식별기의 정확도를 측정합니다.
우선 훈련 데이터와 검증 데이터를 검색합니다.
In[1]:=
![Click for copyable input](assets.ko/measure-classification-performance/In_70.png)
resource = ResourceObject["MNIST"];
trainingData = ResourceData[resource, "TrainingData"];
testData = ResourceData[resource, "TestData"];
In[2]:=
![Click for copyable input](assets.ko/measure-classification-performance/In_71.png)
RandomSample[trainingData, 5]
Out[2]=
![](assets.ko/measure-classification-performance/O_58.png)
28x28 그레이 스케일 이미지를 입력으로 받아들이는 합성곱 신경망을 정의합니다.
In[3]:=
![Click for copyable input](assets.ko/measure-classification-performance/In_72.png)
lenet = NetChain[{
ConvolutionLayer[20, 5], Ramp,
PoolingLayer[2, 2],
ConvolutionLayer[50, 5], Ramp,
PoolingLayer[2, 2],
FlattenLayer[],
500, Ramp, 10,
SoftmaxLayer[]},
"Output" -> NetDecoder[{"Class", Range[0, 9]}],
"Input" -> NetEncoder[{"Image", {28, 28}, "Grayscale"}]
]
Out[3]=
![](assets.ko/measure-classification-performance/O_59.png)
3회의 훈련 라운드를 거쳐 네트워크를 훈련합니다.
In[4]:=
![Click for copyable input](assets.ko/measure-classification-performance/In_73.png)
lenet = NetTrain[lenet, trainingData, ValidationSet -> testData,
MaxTrainingRounds -> 3]
Out[4]=
![](assets.ko/measure-classification-performance/O_60.png)
검증 집합에서 무작위로 추출된 이미지에서 직접 훈련된 네트워크를 평가합니다.
In[5]:=
![Click for copyable input](assets.ko/measure-classification-performance/In_74.png)
imgs = Keys @ RandomSample[testData, 5];
Thread[imgs -> lenet[imgs]]
Out[5]=
![](assets.ko/measure-classification-performance/O_61.png)
훈련된 네트워크 및 검증 집합에서 ClassifierMeasurements 객체를 생성합니다.
In[6]:=
![Click for copyable input](assets.ko/measure-classification-performance/In_75.png)
cm = ClassifierMeasurements[lenet, testData]
Out[6]=
![](assets.ko/measure-classification-performance/O_62.png)
검증 집합에서의 네트워크의 정확성을 얻습니다.
In[7]:=
![Click for copyable input](assets.ko/measure-classification-performance/In_76.png)
cm["Accuracy"]
Out[7]=
![](assets.ko/measure-classification-performance/O_63.png)
8로 잘못 분류 된 3을 목록으로 만듭니다.
In[8]:=
![Click for copyable input](assets.ko/measure-classification-performance/In_77.png)
cm[{"Examples", 3 -> 8}]
Out[8]=
![](assets.ko/measure-classification-performance/O_64.png)
검증 집합에 대한 네트워크 예측 혼동 행렬의 플롯을 얻습니다.
In[9]:=
![Click for copyable input](assets.ko/measure-classification-performance/In_78.png)
cm["ConfusionMatrixPlot"]
Out[9]=
![](assets.ko/measure-classification-performance/O_65.png)