分类性能评估
测量用手写体数字的 MNIST 数据库训练的数字识别器的准确度.
首先获取训练和验证数据.
In[1]:=
![Click for copyable input](assets.zh/measure-classification-performance/In_70.png)
resource = ResourceObject["MNIST"];
trainingData = ResourceData[resource, "TrainingData"];
testData = ResourceData[resource, "TestData"];
In[2]:=
![Click for copyable input](assets.zh/measure-classification-performance/In_71.png)
RandomSample[trainingData, 5]
Out[2]=
![](assets.zh/measure-classification-performance/O_58.png)
定义一个接受 28×28 灰度图像为输入的卷积神经网络.
In[3]:=
![Click for copyable input](assets.zh/measure-classification-performance/In_72.png)
lenet = NetChain[{
ConvolutionLayer[20, 5], Ramp,
PoolingLayer[2, 2],
ConvolutionLayer[50, 5], Ramp,
PoolingLayer[2, 2],
FlattenLayer[],
500, Ramp, 10,
SoftmaxLayer[]},
"Output" -> NetDecoder[{"Class", Range[0, 9]}],
"Input" -> NetEncoder[{"Image", {28, 28}, "Grayscale"}]
]
Out[3]=
![](assets.zh/measure-classification-performance/O_59.png)
对网络做三轮训练.
In[4]:=
![Click for copyable input](assets.zh/measure-classification-performance/In_73.png)
lenet = NetTrain[lenet, trainingData, ValidationSet -> testData,
MaxTrainingRounds -> 3]
Out[4]=
![](assets.zh/measure-classification-performance/O_60.png)
在从验证集上随机抽样的图像上直接运行经过训练的网络.
In[5]:=
![Click for copyable input](assets.zh/measure-classification-performance/In_74.png)
imgs = Keys @ RandomSample[testData, 5];
Thread[imgs -> lenet[imgs]]
Out[5]=
![](assets.zh/measure-classification-performance/O_61.png)
从经过训练的网络创建一个 ClassifierMeasurements 对象和验证集.
In[6]:=
![Click for copyable input](assets.zh/measure-classification-performance/In_75.png)
cm = ClassifierMeasurements[lenet, testData]
Out[6]=
![](assets.zh/measure-classification-performance/O_62.png)
获取网络在验证集上的精确度.
In[7]:=
![Click for copyable input](assets.zh/measure-classification-performance/In_76.png)
cm["Accuracy"]
Out[7]=
![](assets.zh/measure-classification-performance/O_63.png)
列出被误判为 8 的 3.
In[8]:=
![Click for copyable input](assets.zh/measure-classification-performance/In_77.png)
cm[{"Examples", 3 -> 8}]
Out[8]=
![](assets.zh/measure-classification-performance/O_64.png)
获取验证集上网络预测的混淆矩阵的图形.
In[9]:=
![Click for copyable input](assets.zh/measure-classification-performance/In_78.png)
cm["ConfusionMatrixPlot"]
Out[9]=
![](assets.zh/measure-classification-performance/O_65.png)