분류 성능의 측정
MNIST의 육필 숫자 데이터베이스에서 훈련된 숫자 식별기의 정확도를 측정합니다.
우선 훈련 데이터와 검증 데이터를 검색합니다.
In[1]:=
resource = ResourceObject["MNIST"];
trainingData = ResourceData[resource, "TrainingData"];
testData = ResourceData[resource, "TestData"];In[2]:=
RandomSample[trainingData, 5]Out[2]=
28x28 그레이 스케일 이미지를 입력으로 받아들이는 합성곱 신경망을 정의합니다.
In[3]:=
lenet = NetChain[{
ConvolutionLayer[20, 5], Ramp,
PoolingLayer[2, 2],
ConvolutionLayer[50, 5], Ramp,
PoolingLayer[2, 2],
FlattenLayer[],
500, Ramp, 10,
SoftmaxLayer[]},
"Output" -> NetDecoder[{"Class", Range[0, 9]}],
"Input" -> NetEncoder[{"Image", {28, 28}, "Grayscale"}]
]Out[3]=
3회의 훈련 라운드를 거쳐 네트워크를 훈련합니다.
In[4]:=
lenet = NetTrain[lenet, trainingData, ValidationSet -> testData,
MaxTrainingRounds -> 3]Out[4]=
검증 집합에서 무작위로 추출된 이미지에서 직접 훈련된 네트워크를 평가합니다.
In[5]:=
imgs = Keys @ RandomSample[testData, 5];
Thread[imgs -> lenet[imgs]]Out[5]=
훈련된 네트워크 및 검증 집합에서 ClassifierMeasurements 객체를 생성합니다.
In[6]:=
cm = ClassifierMeasurements[lenet, testData]Out[6]=
검증 집합에서의 네트워크의 정확성을 얻습니다.
In[7]:=
cm["Accuracy"]Out[7]=
8로 잘못 분류 된 3을 목록으로 만듭니다.
In[8]:=
cm[{"Examples", 3 -> 8}]Out[8]=
검증 집합에 대한 네트워크 예측 혼동 행렬의 플롯을 얻습니다.
In[9]:=
cm["ConfusionMatrixPlot"]Out[9]=
