Données institutionnelles de la Federal Deposit Insurance Corporation
La Federal Deposit Insurance Corporation (FDIC) est une agence gouvernementale américaine indépendante chargée d'assurer les transferts de fonds dans les institutions financières américaines. Actuellement, les transferts de fonds dans les institutions membres sont assurés jusqu'à 250 000 dollars. Nous étudions ici les avoirs, la répartition par taille et la dispersion géographique des institutions membres.
Tout d'abord, chargez un magasin d'entités de données FDIC en tant que ResourceObject.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_216.png)
fdic = ResourceData[
ResourceObject[
Association[
"Name" -> "FDIC Institution EntityStore",
"UUID" -> "6f5d37d4-1406-483c-b67c-f58d903d16b1",
"ResourceType" -> "DataResource", "Version" -> "1.0.0",
"Description" -> "A Wolfram Language EntityStore with selected \
data on FDIC insured institutions",
"ContentSize" -> Quantity[0, "Bytes"],
"ContentElements" -> {"EntityStore"}]]]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_150.png)
Enregistrez le magasin pour cette session.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_217.png)
PrependTo[$EntityStores, fdic];
Comptez le nombre d'institutions FDIC.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_218.png)
Length[ents = EntityList["FDICInstitution"]]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_151.png)
Listez quelques-unes des propriétés disponibles dans le magasin d'entités.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_219.png)
EntityProperties["FDICInstitution"] // Sort // Take[#, 20] &
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_152.png)
Visualisez les emplacements géographiques des banques affiliées à la FDIC.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_220.png)
GeoListPlot[EntityList["FDICInstitution"], PlotMarkers -> "$"]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_153.png)
Affichez la répartition des rangs dans un diagramme log-log.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_221.png)
ListLogLogPlot[
Reverse@Sort[EntityValue["FDICInstitution", "TotalAssets"]],
AxesLabel -> Automatic, PlotStyle -> PointSize[Medium]]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_154.png)
Tracez la courbe des employés en fonction des actifs.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_222.png)
empVsAssets =
EntityValue[
"FDICInstitution", {"TotalEmployeeNumber", "TotalAssets"}];
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_223.png)
ListLogLogPlot[empVsAssets, AxesLabel -> Automatic]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_155.png)
Étiquetez les six institutions les plus importantes.
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_156.png)
Tracez les passifs en fonction des actifs.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_225.png)
assetsVsLiability =
EntityValue["FDICInstitution", {"TotalAssets", "TotalLiabilities"}];
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_226.png)
ListLogLogPlot[assetsVsLiability, AxesLabel -> Automatic]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_157.png)
Tracez les prêts nets et le crédit-bail en fonction du total des transferts de fonds, ainsi qu'un ajustement.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_227.png)
loanVsDeposit =
EntityValue[
"FDICInstitution", {"NetLoansAndLeases", "TotalDeposits"}];
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_228.png)
nmf = NonlinearModelFit[
Select[QuantityMagnitude /@ loanVsDeposit, Min[#] > 0 &],
c + a x^\[Alpha], {a, \[Alpha], c}, x]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_158.png)
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_229.png)
Show[ListPlot[loanVsDeposit],
Plot[Evaluate[Normal[nmf]], {x, 0, 10^10}, PlotStyle -> Red,
AxesLabel -> Automatic]]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_159.png)
Comparez les fonds propres de catégorie 1 (sûrs) et de catégorie 2 (plus risqués) au total des actifs.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_230.png)
{tierOneCapitalToAssets,
tierTwoCapitalToAssetsCapitalToAssets} = (Divide @@@
EntityValue[
"FDICInstitution", {#, "TotalAssets"}]) & /@ {"TierOneCapital",
"TierTwoRiskBasedCapital"};
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_231.png)
Histogram[{tierOneCapitalToAssets,
tierTwoCapitalToAssetsCapitalToAssets}, {0, 0.3, 0.01},
ChartLegends -> {"Tier 1", "Tier 2"},
PlotLabel -> "Capital/Assets Ratio"]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_160.png)
Récupérez la répartition des actifs en tant qu'"EntityAssociation".
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_232.png)
dat = EntityValue["FDICInstitution", "TotalAssets",
"EntityAssociation"];
Tracez la répartition des actifs.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_233.png)
Histogram[dat, "Log", AxesLabel -> Automatic]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_161.png)
Affichez l'emplacement des banques dont les actifs sont supérieurs à 5 milliards et à 300 milliards de dollars.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_234.png)
GeoListPlot[
Keys[Select[dat,
GreaterThan[Quantity[#, "USDollars"]]]]] & /@ {5*^9, 300*^9}
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_162.png)
Découvrez graphiquement que les 10 premières banques détiennent plus d'actifs que les 6121 autres réunies.
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_163.png)
Trouvez les banques ayant les 1 % de transferts de fonds les plus élevés.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_236.png)
dat1 = EntityValue["FDICInstitution", "TotalDeposits",
"EntityAssociation"];
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_237.png)
{bottom1percent, top1percent} =
Quantile[values = Values[dat1], {0.01, 0.99}]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_164.png)
Tracez-les sur une carte.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_238.png)
GeoListPlot[Keys[Select[dat1, GreaterThan[top1percent]]]]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_165.png)
La répartition des actifs par ville répond de manière remarquable à la loi de Benford.
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_166.png)
Affichez les banques ayant le plus important pouvoir d'achat financier.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_242.png)
dataSet3[TakeLargestBy["FinancialLeverage", 10]]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_167.png)
Tracez la répartition des pouvoirs d'achat financiers.
![Click for copyable input](assets.en/federal-deposit-insurance-corporation-institutiona/In_243.png)
Histogram[dataSet3[All, "FinancialLeverage"], {0, 20, 0.5},
PlotLabel -> "FDIC banks Financial Leverage distribution"]
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_168.png)
Explorez graphiquement la relation entre les actifs, les actifs à long terme et les passifs.
![](assets.en/federal-deposit-insurance-corporation-institutiona/O_169.png)