Данные от федеральной корпорации страхования депозитов
Федеральная корпорация по страхованию депозитов (FDIC) является независимым правительственным агентством США, которое занимается страхованием вкладов американских финансовых учреждений. В настоящее время вклады финансовых учреждений застрахованы на сумму до $250000. В данном примере мы рассмотрим данные о застрахованных организациях, распределение размеров их фондов, а также их географическую рассредоточенность.
Во-первых, загрузим данные FDIC в качестве ресурсного объекта, ResourceObject.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_216.png)
fdic = ResourceData[
ResourceObject[
Association[
"Name" -> "FDIC Institution EntityStore",
"UUID" -> "6f5d37d4-1406-483c-b67c-f58d903d16b1",
"ResourceType" -> "DataResource", "Version" -> "1.0.0",
"Description" -> "A Wolfram Language EntityStore with selected \
data on FDIC insured institutions",
"ContentSize" -> Quantity[0, "Bytes"],
"ContentElements" -> {"EntityStore"}]]]
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_150.png)
Зарегистрируем созданный информационный объект.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_217.png)
PrependTo[$EntityStores, fdic];
Посчитаем количество учреждений, застрахованных через FDIC.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_218.png)
Length[ents = EntityList["FDICInstitution"]]
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_151.png)
Перечислим некоторые из доступных свойств созданного информационного объекта.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_219.png)
EntityProperties["FDICInstitution"] // Sort // Take[#, 20] &
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_152.png)
Визуализируем географическое расположение банков, чьи вклады застрахованы FDIC.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_220.png)
GeoListPlot[EntityList["FDICInstitution"], PlotMarkers -> "$"]
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_153.png)
Отобразим распределение рангов застрахованных организаций в логарифмическом масштабе.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_221.png)
ListLogLogPlot[
Reverse@Sort[EntityValue["FDICInstitution", "TotalAssets"]],
AxesLabel -> Automatic, PlotStyle -> PointSize[Medium]]
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_154.png)
Отобразим на графике количество сотрудников застрахованных организаций и размеры активов данных организаций.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_222.png)
empVsAssets =
EntityValue[
"FDICInstitution", {"TotalEmployeeNumber", "TotalAssets"}];
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_223.png)
ListLogLogPlot[empVsAssets, AxesLabel -> Automatic]
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_155.png)
Определим шесть крупнейших застрахованных учреждений.
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_156.png)
Отобразим на графике размер задолженности и размер активов.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_225.png)
assetsVsLiability =
EntityValue["FDICInstitution", {"TotalAssets", "TotalLiabilities"}];
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_226.png)
ListLogLogPlot[assetsVsLiability, AxesLabel -> Automatic]
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_157.png)
Сравним на графике объем кредитов и лизинга с общей суммой депозитов.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_227.png)
loanVsDeposit =
EntityValue[
"FDICInstitution", {"NetLoansAndLeases", "TotalDeposits"}];
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_228.png)
nmf = NonlinearModelFit[
Select[QuantityMagnitude /@ loanVsDeposit, Min[#] > 0 &],
c + a x^\[Alpha], {a, \[Alpha], c}, x]
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_158.png)
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_229.png)
Show[ListPlot[loanVsDeposit],
Plot[Evaluate[Normal[nmf]], {x, 0, 10^10}, PlotStyle -> Red,
AxesLabel -> Automatic]]
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_159.png)
Сравним 1 эшелон (активы с низкой степенью риска) и 2 эшелон (активы с высокой степенью риска) капитала с общей суммой активов.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_230.png)
{tierOneCapitalToAssets,
tierTwoCapitalToAssetsCapitalToAssets} = (Divide @@@
EntityValue[
"FDICInstitution", {#, "TotalAssets"}]) & /@ {"TierOneCapital",
"TierTwoRiskBasedCapital"};
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_231.png)
Histogram[{tierOneCapitalToAssets,
tierTwoCapitalToAssetsCapitalToAssets}, {0, 0.3, 0.01},
ChartLegends -> {"Tier 1", "Tier 2"},
PlotLabel -> "Capital/Assets Ratio"]
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_160.png)
Получим распределение активов как информационный объект типа "EntityAssociation".
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_232.png)
dat = EntityValue["FDICInstitution", "TotalAssets",
"EntityAssociation"];
Отобразим на графике распределение застрахованных активов.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_233.png)
Histogram[dat, "Log", AxesLabel -> Automatic]
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_161.png)
Покажем географическое расположение банков с активами более 5 миллиардов и 300 миллиардов долларов.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_234.png)
GeoListPlot[
Keys[Select[dat,
GreaterThan[Quantity[#, "USDollars"]]]]] & /@ {5*^9, 300*^9}
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_162.png)
На графике видно, что 10 наиболее крупных банков имеют активы, чьи размеры превышают размеры активов всех остальные 6121 банков.
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_163.png)
Определим банки с самыми крупными депозитами.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_236.png)
dat1 = EntityValue["FDICInstitution", "TotalDeposits",
"EntityAssociation"];
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_237.png)
{bottom1percent, top1percent} =
Quantile[values = Values[dat1], {0.01, 0.99}]
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_164.png)
Обозначим их на карте.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_238.png)
GeoListPlot[Keys[Select[dat1, GreaterThan[top1percent]]]]
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_165.png)
Распределение активов по городам в значительной степени соответствует закону Бенфорда.
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_166.png)
Покажем на карте банки с наиболее значительным плечом финансового рычага.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_242.png)
dataSet3[TakeLargestBy["FinancialLeverage", 10]]
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_167.png)
Построим распределение размеров финансового левериджа.
![Click for copyable input](assets.ru/federal-deposit-insurance-corporation-institutiona/In_243.png)
Histogram[dataSet3[All, "FinancialLeverage"], {0, 20, 0.5},
PlotLabel -> "FDIC banks Financial Leverage distribution"]
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_168.png)
Рассмотрим на графике взаимосвязь между активами, долгосрочными активами, и платежными обязательствами.
![](assets.ru/federal-deposit-insurance-corporation-institutiona/O_169.png)