Dados institucionais da Corporação Federal de Seguro de Depósitos
A Corporação Federal de Seguro de Depósitos (FDIC) é uma agência governamental independente americana cuja função é garantir os depósitos bancários em instituições financeiras nos EUA. Atualmente, depósitos em instituições membros são segurados até U$ 250.000. Aqui, as participações, distribuição de tamanho e dispersão geográfica das instituições membros são exploradas.
Primeiro, carregue um banco de dados de entidades da FDIC como um ResourceObject.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_220.png)
fdic = ResourceData[
ResourceObject[
Association[
"Name" -> "FDIC Institution EntityStore",
"UUID" -> "6f5d37d4-1406-483c-b67c-f58d903d16b1",
"ResourceType" -> "DataResource", "Version" -> "1.0.0",
"Description" -> "A Wolfram Language EntityStore with selected \
data on FDIC insured institutions",
"ContentSize" -> Quantity[0, "Bytes"],
"ContentElements" -> {"EntityStore"}]]]
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_148.png)
Registre o banco de dados para esta sessão.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_221.png)
PrependTo[$EntityStores, fdic];
Conte o número de instituições da FDIC.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_222.png)
Length[ents = EntityList["FDICInstitution"]]
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_149.png)
Liste algumas das propriedades disponíveis no banco de dados de entidades.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_223.png)
EntityProperties["FDICInstitution"] // Sort // Take[#, 20] &
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_150.png)
Visualize as localizações geográficas dos bancos afiliados à FDIC.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_224.png)
GeoListPlot[EntityList["FDICInstitution"], PlotMarkers -> "$"]
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_151.png)
Mostre a distrubuição da classificação em um gráfico tipo log-log.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_225.png)
ListLogLogPlot[
Reverse@Sort[EntityValue["FDICInstitution", "TotalAssets"]],
AxesLabel -> Automatic, PlotStyle -> PointSize[Medium]]
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_152.png)
Faça um gráfico de funcionário versus ativos.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_226.png)
empVsAssets =
EntityValue[
"FDICInstitution", {"TotalEmployeeNumber", "TotalAssets"}];
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_227.png)
ListLogLogPlot[empVsAssets, AxesLabel -> Automatic]
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_153.png)
Identifique as seis maiores instituições.
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_154.png)
Faça um gráfico de passivos versus ativos.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_229.png)
assetsVsLiability =
EntityValue["FDICInstitution", {"TotalAssets", "TotalLiabilities"}];
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_230.png)
ListLogLogPlot[assetsVsLiability, AxesLabel -> Automatic]
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_155.png)
Faça um gráfico empréstimos e leasings líquidos vs. totais de depósitos , junto com um ajuste.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_231.png)
loanVsDeposit =
EntityValue[
"FDICInstitution", {"NetLoansAndLeases", "TotalDeposits"}];
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_232.png)
nmf = NonlinearModelFit[
Select[QuantityMagnitude /@ loanVsDeposit, Min[#] > 0 &],
c + a x^\[Alpha], {a, \[Alpha], c}, x]
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_156.png)
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_233.png)
Show[ListPlot[loanVsDeposit],
Plot[Evaluate[Normal[nmf]], {x, 0, 10^10}, PlotStyle -> Red,
AxesLabel -> Automatic]]
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_157.png)
Compare o nível 1 (seguro) e o capital do nível 2 capital (arriscado) com os ativos totais.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_234.png)
{tierOneCapitalToAssets,
tierTwoCapitalToAssetsCapitalToAssets} = (Divide @@@
EntityValue[
"FDICInstitution", {#, "TotalAssets"}]) & /@ {"TierOneCapital",
"TierTwoRiskBasedCapital"};
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_235.png)
Histogram[{tierOneCapitalToAssets,
tierTwoCapitalToAssetsCapitalToAssets}, {0, 0.3, 0.01},
ChartLegends -> {"Tier 1", "Tier 2"},
PlotLabel -> "Capital/Assets Ratio"]
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_158.png)
Extraia a distribuição de ativos como um "EntityAssociation".
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_236.png)
dat = EntityValue["FDICInstitution", "TotalAssets",
"EntityAssociation"];
Faça um gráfico da distribuição de ativos.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_237.png)
Histogram[dat, "Log", AxesLabel -> Automatic]
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_159.png)
Mostre a localização dos bancos com ativos maiores que 5 bilhões e 300 bilhões de dólares.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_238.png)
GeoListPlot[
Keys[Select[dat,
GreaterThan[Quantity[#, "USDollars"]]]]] & /@ {5*^9, 300*^9}
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_160.png)
Descubra com o gráfico que os 10 maiores bancos possuem mais ativos que os restantes 6.121 combinados.
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_161.png)
Encontre bancos com o maior 1% dos depósitos.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_240.png)
dat1 = EntityValue["FDICInstitution", "TotalDeposits",
"EntityAssociation"];
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_241.png)
{bottom1percent, top1percent} =
Quantile[values = Values[dat1], {0.01, 0.99}]
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_162.png)
Faça um gráfico.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_242.png)
GeoListPlot[Keys[Select[dat1, GreaterThan[top1percent]]]]
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_163.png)
A distribuição dos ativos por cidade satisfaz a lei de Benford notavelmente.
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_164.png)
Mostre bancos com a maior alavancagem financeira.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_246.png)
dataSet3[TakeLargestBy["FinancialLeverage", 10]]
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_165.png)
Faça um gráfico distribuição das alavancagens financeiras.
![Click for copyable input](assets.pt-br/federal-deposit-insurance-corporation-institutiona/In_247.png)
Histogram[dataSet3[All, "FinancialLeverage"], {0, 20, 0.5},
PlotLabel -> "FDIC banks Financial Leverage distribution"]
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_166.png)
Explore no gráfico a relação entre os ativos, ativos de longo prazo, e passivos.
![](assets.pt-br/federal-deposit-insurance-corporation-institutiona/O_167.png)