Le yoga pour la santé et la connaissance
La base de connaissances de Wolfram comprend un jeu de données sur les poses de yoga. Ainsi, les relations entre les postures, leurs niveaux de difficulté, les muscles qu'elles impliquent, leurs durées et bien d'autres caractéristiques peuvent être explorées et étudiées d'une manière simple, puissante, précise et entièrement programmatique.
Formez et visualisez les relations entre les postures de yoga sur la base des relations "PreparatoryPoses", en commençant par la pose du scorpion.
![Click for copyable input](assets.en/yoga-for-health-and-knowledge/In_89.png)
poseGraph =
NestGraph[Cases[EntityValue[#, "PreparatoryPoses"], _Entity] &,
Entity["YogaPose", "ScorpionPose"], 4, VertexLabels -> "Name",
VertexLabelStyle -> LightGray]
![](assets.en/yoga-for-health-and-knowledge/O_68.png)
Affichez des schémas de différentes poses.
![Click for copyable input](assets.en/yoga-for-health-and-knowledge/In_90.png)
With[{v = Take[VertexList[poseGraph], 5]},
schm = Rule @@@ Transpose[{v, EntityValue[v, "Schematic"]}]
] // Column
![](assets.en/yoga-for-health-and-knowledge/O_69.png)
Réalisez un tracé des poses regroupées par « communautés » qui partagent des liens entre elles.
![Click for copyable input](assets.en/yoga-for-health-and-knowledge/In_91.png)
CommunityGraphPlot[EdgeList[poseGraph] /. e_DirectedEdge :> Reverse@e,
VertexLabels -> Placed["Name", Tooltip]]
![](assets.en/yoga-for-health-and-knowledge/O_70.png)
Comptez le nombre de muscles contractés dans la série de poses de la séquence de yoga primaire Ashtanga et faites un tracé par rapport au nombre de muscles engagés.
![](assets.en/yoga-for-health-and-knowledge/O_71.png)
Trouvez les muscles qui sont étirés dans la série de poses de la salutation au soleil A et visualisez le muscle le plus souvent étiré.
![Click for copyable input](assets.en/yoga-for-health-and-knowledge/In_94.png)
muscles = (SortBy[
Tally[DeleteMissing[
Flatten[EntityValue[
Cases[Entity["YogaSequence", "SunSalutationA"][
"PrimaryPoseSequence"], _Entity, Infinity],
"StretchedMuscles"]]]], Last] // Reverse) // Take[#, 20] &
![](assets.en/yoga-for-health-and-knowledge/O_72.png)
Visualisez le muscle le plus fréquemment étiré.
![Click for copyable input](assets.en/yoga-for-health-and-knowledge/In_95.png)
EntityValue[muscles[[1, 1]], "RegionalLocationImage"]
![](assets.en/yoga-for-health-and-knowledge/O_73.png)
Utilisez une classe d'entités implicitement définie pour trouver et visualiser des postures de yoga d'intensité moyenne pour débutants qui étirent les jambes et renforcent le tronc.
![Click for copyable input](assets.en/yoga-for-health-and-knowledge/In_96.png)
EntityList[
Entity["YogaPose", {"ExperienceLevel" -> "Beginner",
"IntensityLevel" -> "Medium",
"SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"],
"SitesOfImprovedStrength" ->
Entity["AnatomicalStructure", "Abdomen"]}]]
![](assets.en/yoga-for-health-and-knowledge/O_74.png)
Visualisez des schémas de ces poses sous la forme d'une association d'entités.
![Click for copyable input](assets.en/yoga-for-health-and-knowledge/In_97.png)
EntityList[
Entity["YogaPose", {"ExperienceLevel" -> "Beginner",
"IntensityLevel" -> "Medium",
"SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"],
"SitesOfImprovedStrength" ->
Entity["AnatomicalStructure", "Abdomen"]}]];
EntityValue[Take[%, 5], "Schematic", "EntityAssociation"]
![](assets.en/yoga-for-health-and-knowledge/O_75.png)
Affichez des postures de yoga avancées qui renforcent l'iliopsoas et étirent les ischio-jambiers.
![Click for copyable input](assets.en/yoga-for-health-and-knowledge/In_98.png)
EntityValue[
Entity["YogaPose", {"ExperienceLevel" -> "Advanced",
"PrimaryContractedMuscles" ->
Entity["AnatomicalStructure", "Iliopsoas"],
"StretchedMuscles" ->
Entity["AnatomicalStructure",
"SetOfHamstringMuscles"]}], "Schematic", "EntityAssociation"]
![](assets.en/yoga-for-health-and-knowledge/O_76.png)
Trouvez des séquences de yoga d'une durée comprise entre 30 et 60 minutes.
![Click for copyable input](assets.en/yoga-for-health-and-knowledge/In_99.png)
EntityList@
Entity["YogaSequence", {"EstimatedDuration" ->
Quantity[ Interval[{30, 60}], "Minutes"]}]
![](assets.en/yoga-for-health-and-knowledge/O_77.png)