Оздоровительные и познавательные аспекты йоги
Wolfram Knowledgebase включает в себя набор данных о позах йоги. Взаимосвязанность поз, их уровни сложности, задействуемые мышцы, продолжительность поз, а также многие другие характеристики могут быть изучены и исследованы точным, полностью программным путем.
Визуализируем взаимосвязь между позами йоги, относящимися к подготовительным позам ("PreparatoryPoses"), начиная с позы скорпиона.
![Click for copyable input](assets.ru/yoga-for-health-and-knowledge/In_89.png)
poseGraph =
NestGraph[Cases[EntityValue[#, "PreparatoryPoses"], _Entity] &,
Entity["YogaPose", "ScorpionPose"], 4, VertexLabels -> "Name",
VertexLabelStyle -> LightGray]
![](assets.ru/yoga-for-health-and-knowledge/O_68.png)
Рассмотрим схематичные изображения различных поз.
![Click for copyable input](assets.ru/yoga-for-health-and-knowledge/In_90.png)
With[{v = Take[VertexList[poseGraph], 5]},
schm = Rule @@@ Transpose[{v, EntityValue[v, "Schematic"]}]
] // Column
![](assets.ru/yoga-for-health-and-knowledge/O_69.png)
Составим график поз, сгруппированных по общим принципам.
![Click for copyable input](assets.ru/yoga-for-health-and-knowledge/In_91.png)
CommunityGraphPlot[EdgeList[poseGraph] /. e_DirectedEdge :> Reverse@e,
VertexLabels -> Placed["Name", Tooltip]]
![](assets.ru/yoga-for-health-and-knowledge/O_70.png)
Подсчитаем количество мышц, задействованных в первой серии поз в Аштанге.
![](assets.ru/yoga-for-health-and-knowledge/O_71.png)
Определим мышцы, которые растягиваются в серии поз Сурья Намаскар A и визуализируем наиболее часто растянутую мышцу.
![Click for copyable input](assets.ru/yoga-for-health-and-knowledge/In_94.png)
muscles = (SortBy[
Tally[DeleteMissing[
Flatten[EntityValue[
Cases[Entity["YogaSequence", "SunSalutationA"][
"PrimaryPoseSequence"], _Entity, Infinity],
"StretchedMuscles"]]]], Last] // Reverse) // Take[#, 20] &
![](assets.ru/yoga-for-health-and-knowledge/O_72.png)
Bизуализируем наиболее часто растянутую мышцу.
![Click for copyable input](assets.ru/yoga-for-health-and-knowledge/In_95.png)
EntityValue[muscles[[1, 1]], "RegionalLocationImage"]
![](assets.ru/yoga-for-health-and-knowledge/O_73.png)
Воспользуемся неявно определенным классом сущностей, чтобы найти и визуализировать позы йоги для начинающих средней интенсивности, которые помогают растянуть мышцы ног и укрепить туловище.
![Click for copyable input](assets.ru/yoga-for-health-and-knowledge/In_96.png)
EntityList[
Entity["YogaPose", {"ExperienceLevel" -> "Beginner",
"IntensityLevel" -> "Medium",
"SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"],
"SitesOfImprovedStrength" ->
Entity["AnatomicalStructure", "Abdomen"]}]]
![](assets.ru/yoga-for-health-and-knowledge/O_74.png)
Рассмотрим схематичные изображения этих поз.
![Click for copyable input](assets.ru/yoga-for-health-and-knowledge/In_97.png)
EntityList[
Entity["YogaPose", {"ExperienceLevel" -> "Beginner",
"IntensityLevel" -> "Medium",
"SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"],
"SitesOfImprovedStrength" ->
Entity["AnatomicalStructure", "Abdomen"]}]];
EntityValue[Take[%, 5], "Schematic", "EntityAssociation"]
![](assets.ru/yoga-for-health-and-knowledge/O_75.png)
Запросим позы йоги продвинутого уровня, которые укрепляют пояснично-подвздошную мышцу и помогают растянуть подколенные сухожилия.
![Click for copyable input](assets.ru/yoga-for-health-and-knowledge/In_98.png)
EntityValue[
Entity["YogaPose", {"ExperienceLevel" -> "Advanced",
"PrimaryContractedMuscles" ->
Entity["AnatomicalStructure", "Iliopsoas"],
"StretchedMuscles" ->
Entity["AnatomicalStructure",
"SetOfHamstringMuscles"]}], "Schematic", "EntityAssociation"]
![](assets.ru/yoga-for-health-and-knowledge/O_76.png)
Запросим серии упражнений йоги продолжительностью от 30 до 60 минут.
![Click for copyable input](assets.ru/yoga-for-health-and-knowledge/In_99.png)
EntityList@
Entity["YogaSequence", {"EstimatedDuration" ->
Quantity[ Interval[{30, 60}], "Minutes"]}]
![](assets.ru/yoga-for-health-and-knowledge/O_77.png)