Yoga para saúde e conhecimento
A Wolfram Knowledgebase inclui um conjunto de dados selecionados de posições de yoga. Como resultado, as relações entre as posições, seus níveis de dificuldade, os músculos que envolvem, suas durações, e muitas outras características podem ser exploradas e estudadas de maneira programática simples, poderosa e precisa.
Visualize as relações entre posições de yoga com base nas relações de "PreparatoryPoses", começando pela posição escorpião.
![Click for copyable input](assets.pt-br/yoga-for-health-and-knowledge/In_93.png)
poseGraph =
NestGraph[Cases[EntityValue[#, "PreparatoryPoses"], _Entity] &,
Entity["YogaPose", "ScorpionPose"], 4, VertexLabels -> "Name",
VertexLabelStyle -> LightGray]
![](assets.pt-br/yoga-for-health-and-knowledge/O_66.png)
Mostre imagens esquemáticas de diversas poses.
![Click for copyable input](assets.pt-br/yoga-for-health-and-knowledge/In_94.png)
With[{v = Take[VertexList[poseGraph], 5]},
schm = Rule @@@ Transpose[{v, EntityValue[v, "Schematic"]}]
] // Column
![](assets.pt-br/yoga-for-health-and-knowledge/O_67.png)
Faça um gráfico de posições agrupadas por "comunidades" que compartilham uma relação.
![Click for copyable input](assets.pt-br/yoga-for-health-and-knowledge/In_95.png)
CommunityGraphPlot[EdgeList[poseGraph] /. e_DirectedEdge :> Reverse@e,
VertexLabels -> Placed["Name", Tooltip]]
![](assets.pt-br/yoga-for-health-and-knowledge/O_68.png)
Conte o número de músculos contraídos na série de posições em uma sequência primária de Ashtanga yoga e faça um gráfico do número de músculos envolvidos.
![](assets.pt-br/yoga-for-health-and-knowledge/O_69.png)
Ache os músculos que são alongados na série Saudação ao Sol A e visualize o músculo que é alongado com mais frequência.
![Click for copyable input](assets.pt-br/yoga-for-health-and-knowledge/In_98.png)
muscles = (SortBy[
Tally[DeleteMissing[
Flatten[EntityValue[
Cases[Entity["YogaSequence", "SunSalutationA"][
"PrimaryPoseSequence"], _Entity, Infinity],
"StretchedMuscles"]]]], Last] // Reverse) // Take[#, 20] &
![](assets.pt-br/yoga-for-health-and-knowledge/O_70.png)
Visualize o músculo que é alongado com mais frequência.
![Click for copyable input](assets.pt-br/yoga-for-health-and-knowledge/In_99.png)
EntityValue[muscles[[1, 1]], "RegionalLocationImage"]
![](assets.pt-br/yoga-for-health-and-knowledge/O_71.png)
Use uma classe de entidade definida implicitamente para encontrar e visualizar posições de ioga para iniciantes e de média intensidade que alonguem a perna e fortaleçam o abdomem.
![Click for copyable input](assets.pt-br/yoga-for-health-and-knowledge/In_100.png)
EntityList[
Entity["YogaPose", {"ExperienceLevel" -> "Beginner",
"IntensityLevel" -> "Medium",
"SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"],
"SitesOfImprovedStrength" ->
Entity["AnatomicalStructure", "Abdomen"]}]]
![](assets.pt-br/yoga-for-health-and-knowledge/O_72.png)
Veja imagens esquemáticas dessas posições como uma associação de entidades.
![Click for copyable input](assets.pt-br/yoga-for-health-and-knowledge/In_101.png)
EntityList[
Entity["YogaPose", {"ExperienceLevel" -> "Beginner",
"IntensityLevel" -> "Medium",
"SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"],
"SitesOfImprovedStrength" ->
Entity["AnatomicalStructure", "Abdomen"]}]];
EntityValue[Take[%, 5], "Schematic", "EntityAssociation"]
![](assets.pt-br/yoga-for-health-and-knowledge/O_73.png)
Mostre as posições avançadas de yoga que fortalecem o músculo iliopsoas e alongam os isquiossurais.
![Click for copyable input](assets.pt-br/yoga-for-health-and-knowledge/In_102.png)
EntityValue[
Entity["YogaPose", {"ExperienceLevel" -> "Advanced",
"PrimaryContractedMuscles" ->
Entity["AnatomicalStructure", "Iliopsoas"],
"StretchedMuscles" ->
Entity["AnatomicalStructure",
"SetOfHamstringMuscles"]}], "Schematic", "EntityAssociation"]
![](assets.pt-br/yoga-for-health-and-knowledge/O_74.png)
Encontre sequências de ioga com durações entre 30 e 60 minutos.
![Click for copyable input](assets.pt-br/yoga-for-health-and-knowledge/In_103.png)
EntityList@
Entity["YogaSequence", {"EstimatedDuration" ->
Quantity[ Interval[{30, 60}], "Minutes"]}]
![](assets.pt-br/yoga-for-health-and-knowledge/O_75.png)