회로의 임펄스 응답 찾기
저항 과 인덕터 L로 이루어지며, 시간 의존 전압
에 의해 구동하는 회로의 임펄스 응답을 구합니다.
전류 는 1계 선형 미분 방정식
을 해결함으로써 계산할 수 있습니다.
상미분 방정식의 좌변에 대응하는 미분 연산자를 설정합니다.
In[1]:=
![Click for copyable input](assets.ko/find-the-impulse-response-of-a-circuit/In_135.png)
voltage = L i'[t] + R i[t];
스위치는 처음에는 열려 있다고 가정합니다.
In[2]:=
![Click for copyable input](assets.ko/find-the-impulse-response-of-a-circuit/In_136.png)
init = i[0] == 0;
GreenFunction을 사용하여 회로의 임펄스 응답을 계산합니다.
In[3]:=
![Click for copyable input](assets.ko/find-the-impulse-response-of-a-circuit/In_137.png)
gf[s_, t_] =
GreenFunction[{voltage, init}, i[t], {t, 0, \[Infinity]}, s]
Out[3]=
![](assets.ko/find-the-impulse-response-of-a-circuit/O_74.png)
의 임펄스 응답을 플롯합니다.
In[4]:=
![Click for copyable input](assets.ko/find-the-impulse-response-of-a-circuit/In_138.png)
Plot[gf[s, t] /. {s -> 1, R -> 2, L -> 4}, {t, 0, 7},
PlotTheme -> "Scientific", AxesLabel -> {"t", "i[t]"}]
Out[4]=
![](assets.ko/find-the-impulse-response-of-a-circuit/O_75.png)
단계 전압에 대한 회로의 응답을 계산합니다.
In[5]:=
![Click for copyable input](assets.ko/find-the-impulse-response-of-a-circuit/In_139.png)
v[t_] := HeavisideTheta[t];
In[6]:=
![Click for copyable input](assets.ko/find-the-impulse-response-of-a-circuit/In_140.png)
current = Integrate[gf[s, t] v[s], {s, 0, t}, Assumptions -> t > 0]
Out[6]=
![](assets.ko/find-the-impulse-response-of-a-circuit/O_76.png)
스텝 응답을 시각화합니다.
In[7]:=
![Click for copyable input](assets.ko/find-the-impulse-response-of-a-circuit/In_141.png)
Plot[{current /. {R -> 2, L -> 4}, 0.5} // Evaluate, {t, 0, 6},
PlotTheme -> "Scientific"]
Out[7]=
![](assets.ko/find-the-impulse-response-of-a-circuit/O_77.png)