Conversión al calendario maya
Identifique la época (o fecha de inicio) para el calendario de cuenta larga maya como una fecha juliana.
![Click for copyable input](assets.es/convert-to-the-mayan-calendar/In_59.png)
epoch = JulianDate["Modified",
DateObject[{-3114, 8, 11}, TimeZone -> 0]];
Cree una función para convertir de unidades de calendario de cuenta larga maya a una fecha juliana.
![Click for copyable input](assets.es/convert-to-the-mayan-calendar/In_60.png)
JulianFromMayanLongCount[{baktun_, katun_, tun_, uinal_, kin_}] :=
epoch + 144000*baktun + 7200*katun + 360*tun + 20*uinal + kin
FromJulianDate puede ser usada para probar un ejemplo de entrada.
![Click for copyable input](assets.es/convert-to-the-mayan-calendar/In_61.png)
example = JulianFromMayanLongCount[{7, 17, 18, 19, 2}]
![](assets.es/convert-to-the-mayan-calendar/O_54.png)
![Click for copyable input](assets.es/convert-to-the-mayan-calendar/In_62.png)
FromJulianDate["Modified", example, TimeZone -> 0]
![](assets.es/convert-to-the-mayan-calendar/O_55.png)
Cree una función para convertir directamente de objetos de fecha maya de cuenta larga a gregorianos.
![Click for copyable input](assets.es/convert-to-the-mayan-calendar/In_63.png)
GregorianFromMayanLongCount[date_] := DateValue[
FromJulianDate["Modified",
JulianFromMayanLongCount[date],
TimeZone -> 0],
"Day",
DateObject]
![Click for copyable input](assets.es/convert-to-the-mayan-calendar/In_64.png)
GregorianFromMayanLongCount[{7, 17, 18, 19, 2}]
![](assets.es/convert-to-the-mayan-calendar/O_56.png)
Cree una función para convertir de una fecha juliana a unidades de calendario de cuenta larga maya.
![Click for copyable input](assets.es/convert-to-the-mayan-calendar/In_65.png)
JulianToMayanLongCount[date_] := NumberDecompose[
Floor[date - epoch],
{144000, 7200, 360, 20, 1}
]
JulianDate puede utilizarse para interpretar cualquier entrada de fecha en una fecha juliana, la cual es luego alimentada en una JulianToMayanLongCount.
![Click for copyable input](assets.es/convert-to-the-mayan-calendar/In_66.png)
DateToMayanLongCount[date_] := Block[{$TimeZone = 0},
JulianToMayanLongCount[JulianDate["Modified", date]]
]
Esta función ahora aceptará cualquier entrada de fecha y regresará la correspondiente lista de fechas del calendario de cuenta larga maya.
![Click for copyable input](assets.es/convert-to-the-mayan-calendar/In_67.png)
DateToMayanLongCount["May 4th, 2015"]
![](assets.es/convert-to-the-mayan-calendar/O_57.png)
![Click for copyable input](assets.es/convert-to-the-mayan-calendar/In_68.png)
DateToMayanLongCount[AbsoluteTime[]]
![](assets.es/convert-to-the-mayan-calendar/O_58.png)
![Click for copyable input](assets.es/convert-to-the-mayan-calendar/In_69.png)
DateToMayanLongCount[Today]
![](assets.es/convert-to-the-mayan-calendar/O_59.png)
Estas dos funciones pueden ser utilizadas para convertir de y a el calendario de cuenta larga maya.
![Click for copyable input](assets.es/convert-to-the-mayan-calendar/In_70.png)
DateToMayanLongCount[{1900, 1, 1}]
![](assets.es/convert-to-the-mayan-calendar/O_60.png)
![Click for copyable input](assets.es/convert-to-the-mayan-calendar/In_71.png)
DateToMayanLongCount[{1900, 1, 1}];
GregorianFromMayanLongCount[%]
![](assets.es/convert-to-the-mayan-calendar/O_61.png)