Work with Irregular Time Series 

Draw a sample of Poisson process, sampled at the random times of arrivals.

In[1]:=

X poi = PoissonProcess[1.2]; data = TimeSeries[RandomFunction[poi, {0, 100}]]

Out[1]=

In[2]:=

X RegularlySampledQ[data]

Out[2]=

Visualize the time series.

In[3]:=

X ListPlot[data, Filling -> Axis, ImageSize -> 300]

Out[3]=

Use TimeSeriesMapThread to subtract the mean function from the time series.

In[4]:=

X mf[t_] = Mean[poi[t]]; cdata = TimeSeriesMapThread[Function[{t, x}, x - mf[t]], data];

In[5]:=

X ListPlot[cdata, Filling -> Axis, ImageSize -> 300]

Out[5]=

Use MovingMap to compute mean over a centered constant‐width sliding window.

In[6]:=

X mts = MovingMap[Mean, cdata, {10, Center}, "Reflected"];

show complete Wolfram Language inputhide input

In[7]:=

X ListPlot[{mts, cdata}, Filling -> {1 -> Axis}, Joined -> {False, True}, ImageSize -> 300]

Out[7]=

Use TimeSeriesAggregate to build regularly spaced time series of the largest values in non-overlapping windows of constant width.

In[8]:=

X adata = TimeSeriesAggregate[data, {10, Right}, Max];

show complete Wolfram Language inputhide input

In[9]:=

X ListPlot[{data, TimeSeriesWindow[adata, {0, 100}]}, Filling -> {2 -> Axis}, FillingStyle -> Thick, ImageSize -> 300, PlotLegends -> {"original time series", "max-aggregated time series"}]

Out[9]=

In[10]:=

X RegularlySampledQ[adata]

Out[10]=

Resample with a step of 10 using interpolation of order 0.

In[11]:=

X rdata = TimeSeriesResample[data, 10, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 0}];

show complete Wolfram Language inputhide input

In[12]:=

X ListPlot[{data, rdata}, Filling -> {2 -> Axis}, FillingStyle -> Thick, ImageSize -> 300, PlotLegends -> {"original time series", "resampled time series"}]

Out[12]=

In[13]:=

X RegularlySampledQ[rdata]

Out[13]=

Treat the original time series as regularly sampled for use in functions that require such uniformly sampled input.

In[14]:=

X regdata = TimeSeries[data, TemporalRegularity -> True]

Out[14]=

In[15]:=

X data["Path"] == regdata["Path"]

Out[15]=

In[16]:=

X RegularlySampledQ[regdata]

Out[16]=