Génération de quiz en ligne : Nouveautés de Wolfram Language 11

Génération de quiz en ligne

Il est facile de créer et de déployer des formulaires en utilisant les nouvelles fonctionnalités intégrées. Ces formulaires peuvent être déployés dans le cloud, ce qui permet un stockage permanent et transparent du code et des données, un calcul dans le cloud et un déploiement externe instantané par le biais de documents actifs, d'API, d'applications, etc. Ces fonctionnalités sont illustrées ici par la création et le déploiement de deux « quiz » qui demandent à l'utilisateur d'identifier les grandes villes et certains films populaires, respectivement.

Créez un quiz sur les grandes villes américaines dans le cloud.

In[1]:=

CloudDeploy[
 FormFunction[{"city", 
    "How many of the 10 most populous US cities can you name?"} -> 
   RepeatingElement[
    Restricted[
     "City", {"Country" -> Entity["Country", "UnitedStates"], 
      "Population" -> TakeLargest[10]}], {1, {1, 10}}], 
  GeoListPlot[{#city, 
     Complement[
      EntityList@
       Entity["City", {"Country" -> Entity["Country", "UnitedStates"],
          "Population" -> TakeLargest[10]}], #city]}, 
    GeoLabels -> True, PlotLegends -> {"OK", "Missed"}] &, "PNG"]]

Out[1]=

Consultez le formulaire pour interagir avec lui.

Si l'un des champs ne figure pas parmi les 10 plus grandes villes des États-Unis, le formulaire affichera un message d'échec.

Créez un quiz sur les films dans le cloud.

In[2]:=

CloudDeploy[
 FormFunction[{"movies", 
    "How many of the 10 top grossing movies by Steven Spielberg can \
you name?"} -> 
   RepeatingElement[
    Restricted[
     "Movie", {"Director" -> 
       Entity["Person", "StevenSpielberg::76z25"],
      "DomesticBoxOfficeGross" -> TakeLargest[10]}], {1, {1, 10}}],
  With[{images = 
      EntityValue[
       EntityClass[
        "Movie", {"Director" -> 
          Entity["Person", "StevenSpielberg::76z25"],
         "DomesticBoxOfficeGross" -> TakeLargest[10]}], "Image", 
       "EntityAssociation"]},
    Grid[{
      {"you guessed", Length[#movies], 
       ImageCollage[Values[KeyTake[images, #movies]]]}, {"you missed",
        10 - Length[#movies], 
       ImageCollage[Values[KeyDrop[images, #movies]]]}
      }, Frame -> All, Alignment -> Left]] &]]

Out[2]=