Использование разложения Смита для анализа решётки
Допустим, что решётка была генерирована числами, кратными векторам
и
.
In[1]:=
![Click for copyable input](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/In_91.png)
b1 = {3, -3};
b2 = {2, 1};
In[2]:=
![Click for copyable input](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/In_92.png)
ptsb = Flatten[Table[j b1 + k b2, {j, -12, 12}, {k, -12, 12}], 1];
In[3]:=
![Click for copyable input](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/In_93.png)
graphicsb =
Graphics[{Blue, PointSize[Large], Point@ptsb}, PlotRange -> 10,
Axes -> True]
Out[3]=
![](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/O_81.png)
Допустим, что является матрицей, чьи ряды - это
и
.
In[4]:=
![Click for copyable input](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/In_94.png)
m = {b1, b2};
Разложение Смита выдаёт три матрицы, удовлетворяющие тождеству .
In[5]:=
![Click for copyable input](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/In_95.png)
{u, r, v} = SmithDecomposition[m];
In[6]:=
![Click for copyable input](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/In_96.png)
u.m.v == r
Out[6]=
![](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/O_82.png)
Матрицы и
имеют элементы целых чисел и одну детерминанту.
In[7]:=
![Click for copyable input](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/In_97.png)
{u // MatrixForm, v // MatrixForm, Det[u], Det[v]}
Out[7]=
![](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/O_83.png)
Матрица - это целое число и диагональ. Исходя из её элементов, можно увидеть, что структура группы
- это
или просто
, так как
является тривиальной группой.
In[8]:=
![Click for copyable input](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/In_98.png)
r // MatrixForm
Out[8]//MatrixForm=
![](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/O_84.png)
Умножение правой части тождества на
производит
. Так как
является целым числом и детерминантой
,
генерирует такую же решётку как
, но только проще.
In[9]:=
![Click for copyable input](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/In_99.png)
g = r.Inverse[v];
g // MatrixForm
Out[9]//MatrixForm=
![](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/O_85.png)
Визуализировать решётку, сгенерированную рядами .
In[10]:=
![Click for copyable input](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/In_100.png)
ptsg = Flatten[
Table[j First[g] + k Last[g], {j, -12, 12}, {k, -12, 12}], 1];
In[11]:=
![Click for copyable input](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/In_101.png)
graphicsg =
Graphics[{Red, PointSize[Medium], Point@ptsg}, PlotRange -> 10,
Axes -> True]
Out[11]=
![](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/O_86.png)
Наложение новой решётки на оригинальную доказывает, что они одинаковы.
In[12]:=
![Click for copyable input](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/In_102.png)
Show[{graphicsb, graphicsg}]
Out[12]=
![](assets.ru/use-the-smith-decomposition-to-analyze-a-lattice/O_87.png)