Calcule valores simbólicos propios
Especifique un operador laplaciano en 1D.
In[1]:=
![Click for copyable input](assets.es/compute-symbolic-eigenvalues/In_92.png)
\[ScriptCapitalL] = -Laplacian[u[x], {x}];
Especifique una condición de límite homogénea de Dirichlet.
In[2]:=
![Click for copyable input](assets.es/compute-symbolic-eigenvalues/In_93.png)
\[ScriptCapitalB] = DirichletCondition[u[x] == 0, True];
Encuentre expresiones para los 5 valores propios más pequeños en el intervalo .
In[3]:=
![Click for copyable input](assets.es/compute-symbolic-eigenvalues/In_94.png)
DEigenvalues[{\[ScriptCapitalL], \[ScriptCapitalB]}, u[x], {x, a, b},
5]
Out[3]=
![](assets.es/compute-symbolic-eigenvalues/O_43.png)
Especifique un operador de Airy.
In[4]:=
![Click for copyable input](assets.es/compute-symbolic-eigenvalues/In_95.png)
\[ScriptCapitalL] = -Laplacian[u[x], {x}] + x u[x];
Encuentre los 5 valores propios más pequeños y sus correspondientes funciones propias.
In[5]:=
![Click for copyable input](assets.es/compute-symbolic-eigenvalues/In_96.png)
{vals, funs} =
DEigensystem[{\[ScriptCapitalL], \[ScriptCapitalB]},
u[x], {x, 0, 1}, 5];
Los valores propios son raíces de una ecuación trascendental.
In[6]:=
![Click for copyable input](assets.es/compute-symbolic-eigenvalues/In_97.png)
vals[[1]] // TraditionalForm
Out[6]//TraditionalForm=
![](assets.es/compute-symbolic-eigenvalues/O_44.png)
Calcule un valor propio trascendental con alta precisión.
In[7]:=
![Click for copyable input](assets.es/compute-symbolic-eigenvalues/In_98.png)
N[vals[[1]], 500] // TraditionalForm
Out[7]//TraditionalForm=
![](assets.es/compute-symbolic-eigenvalues/O_45.png)
Visualice las funciones propias.
In[8]:=
![Click for copyable input](assets.es/compute-symbolic-eigenvalues/In_99.png)
Plot[Evaluate[funs + Range[5]], {x, 0, 1}, ImageSize -> Medium,
PlotTheme -> {"Business", "Bare"}, AspectRatio -> 1]
Out[8]=
![](assets.es/compute-symbolic-eigenvalues/O_46.png)