Potencia de un Pokémon
Wolfram Knowledgebase contiene información acerca de íconos de la cultura popular, así como conocimiento científico. Aquí, varias características físicas (puntos de ataque y defensa, peso, color) de la colección de Pokémon son explorados, contrastados y visualizados usando un marco de entidades incorporado.
Represente gráficamente las distribuciones de los puntos de ataque y defensa de todos los Pokémon.
![Click for copyable input](assets.es/pokemon-power/In_78.png)
PairedHistogram[EntityValue["Pokemon", "Attack"],
EntityValue["Pokemon", "Defense"],
ChartLabels -> {"attack", "defense"},
ChartStyle -> {{LightOrange, LightBlue}, None}]
![](assets.es/pokemon-power/O_59.png)
Cree un Dataset de puntos de ataque y defensa para la generación VI de Pokémon y grafíquelos uno contra otro.
![Click for copyable input](assets.es/pokemon-power/In_79.png)
stat = EntityValue[Entity[
"Pokemon", {
"Generation" -> Entity[
"PokemonGeneration", "GenerationVI"]}], {"Attack", "Defense"},
"Dataset"];
![Click for copyable input](assets.es/pokemon-power/In_80.png)
ListPlot[stat,
PlotStyle -> Directive[Opacity[0.5], Orange, PointSize[Medium]],
AxesLabel -> Automatic, LabelingFunction -> None]
![](assets.es/pokemon-power/O_60.png)
Compare y grafique los pesos promedio de un Pokémon de distintas generaciones.
![Click for copyable input](assets.es/pokemon-power/In_81.png)
wg = Normal[
GroupBy[Rule @@@ EntityValue["Pokemon", {"Generation", "Weight"}],
First -> Last, Mean]]
![](assets.es/pokemon-power/O_61.png)
![Click for copyable input](assets.es/pokemon-power/In_82.png)
BarChart3D[wg[[All, 2]], ChartLegends -> wg[[All, 1]],
ChartStyle -> 24]
![](assets.es/pokemon-power/O_62.png)
Use una clase de entidades implícitamente definidas para encontrar los tres Pokémon más pesados.
![Click for copyable input](assets.es/pokemon-power/In_83.png)
EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]]
![](assets.es/pokemon-power/O_63.png)
![Click for copyable input](assets.es/pokemon-power/In_84.png)
EntityList[EntityClass["Pokemon", {"Weight" -> TakeLargest[3]}]];
EntityValue[%, "Generation"]
![](assets.es/pokemon-power/O_64.png)
Use una clase de entidades implícitamente definida para encontrar el Pokémon color amarillo que pesa entre 50 y 100 kg.
![Click for copyable input](assets.es/pokemon-power/In_85.png)
yellowMidweights = EntityList[
Entity["Pokemon", {"PokedexColor" -> "Yellow", "Weight" -> Between[{
Quantity[50, "Kilograms"],
Quantity[100, "Kilograms"]}]}]]
![](assets.es/pokemon-power/O_65.png)
Cree un collage de estos personajes de Pokémon con tamaños basados en sus pesos.
![Click for copyable input](assets.es/pokemon-power/In_86.png)
ImageCollage[
Rule @@@ EntityValue[yellowMidweights, {"Weight", "Image"}],
Background -> White]
![](assets.es/pokemon-power/O_66.png)
Compare los colores de Pokémon en el grupo original (Generación I) y en el grupo más reciente (Generación VI).
![](assets.es/pokemon-power/O_67.png)