Datos institucionales de la Corporación Federal de Seguro de Depósitos
La Corporación Federal de Seguros (FDIC) es una agencia gubernamental de los EE.UU. a cargo de asegurar depósitos en instituciones financieras de los EE.UU. Actualmente, los depósitos en instituciones miembro son asegurados hasta los $250,000. Aquí se exploran las sociedades tenedoras, la distribución de tamaño y la dispersión geográfica de las instituciones miembro.
Primero cargue un almacén de entidades de datos de FDIC data como un ResourceObject.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_216.png)
fdic = ResourceData[
ResourceObject[
Association[
"Name" -> "FDIC Institution EntityStore",
"UUID" -> "6f5d37d4-1406-483c-b67c-f58d903d16b1",
"ResourceType" -> "DataResource", "Version" -> "1.0.0",
"Description" -> "A Wolfram Language EntityStore with selected \
data on FDIC insured institutions",
"ContentSize" -> Quantity[0, "Bytes"],
"ContentElements" -> {"EntityStore"}]]]
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_150.png)
Registre el almacén para esta sesión.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_217.png)
PrependTo[$EntityStores, fdic];
Cuente el número de instituciones de FDIC.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_218.png)
Length[ents = EntityList["FDICInstitution"]]
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_151.png)
Cree una lista de algunas propiedades disponibles en el almacén de entidades.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_219.png)
EntityProperties["FDICInstitution"] // Sort // Take[#, 20] &
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_152.png)
Visualice las ubicaciones geográficas de los bancos afiliados a FDIC.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_220.png)
GeoListPlot[EntityList["FDICInstitution"], PlotMarkers -> "$"]
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_153.png)
Muestre la distribución de rango en un gráfico tipo log-log.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_221.png)
ListLogLogPlot[
Reverse@Sort[EntityValue["FDICInstitution", "TotalAssets"]],
AxesLabel -> Automatic, PlotStyle -> PointSize[Medium]]
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_154.png)
Grafique los empleados vs. activos.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_222.png)
empVsAssets =
EntityValue[
"FDICInstitution", {"TotalEmployeeNumber", "TotalAssets"}];
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_223.png)
ListLogLogPlot[empVsAssets, AxesLabel -> Automatic]
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_155.png)
Etiquete las seis instituciones más grandes.
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_156.png)
Represente gráficamente activos vs. pasivos.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_225.png)
assetsVsLiability =
EntityValue["FDICInstitution", {"TotalAssets", "TotalLiabilities"}];
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_226.png)
ListLogLogPlot[assetsVsLiability, AxesLabel -> Automatic]
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_157.png)
Grafique los créditos netos y contratos vs. el total de depósitos junto con un ajuste.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_227.png)
loanVsDeposit =
EntityValue[
"FDICInstitution", {"NetLoansAndLeases", "TotalDeposits"}];
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_228.png)
nmf = NonlinearModelFit[
Select[QuantityMagnitude /@ loanVsDeposit, Min[#] > 0 &],
c + a x^\[Alpha], {a, \[Alpha], c}, x]
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_158.png)
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_229.png)
Show[ListPlot[loanVsDeposit],
Plot[Evaluate[Normal[nmf]], {x, 0, 10^10}, PlotStyle -> Red,
AxesLabel -> Automatic]]
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_159.png)
Compare el Nivel 1 (seguro) y el capital de Nivel 2 (riesgoso) con los activos totales.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_230.png)
{tierOneCapitalToAssets,
tierTwoCapitalToAssetsCapitalToAssets} = (Divide @@@
EntityValue[
"FDICInstitution", {#, "TotalAssets"}]) & /@ {"TierOneCapital",
"TierTwoRiskBasedCapital"};
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_231.png)
Histogram[{tierOneCapitalToAssets,
tierTwoCapitalToAssetsCapitalToAssets}, {0, 0.3, 0.01},
ChartLegends -> {"Tier 1", "Tier 2"},
PlotLabel -> "Capital/Assets Ratio"]
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_160.png)
Recupere la distribución de activos como una "EntityAssociation".
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_232.png)
dat = EntityValue["FDICInstitution", "TotalAssets",
"EntityAssociation"];
Grafique la distribución de activos.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_233.png)
Histogram[dat, "Log", AxesLabel -> Automatic]
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_161.png)
Muestre las ubicaciones de los bancos con activos mayores a 5 billones y 300 billones de dólares estadounidenses.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_234.png)
GeoListPlot[
Keys[Select[dat,
GreaterThan[Quantity[#, "USDollars"]]]]] & /@ {5*^9, 300*^9}
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_162.png)
Descubra gráficamente que los 10 bancos principales tienen más activos que los restantes 6121 combinados.
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_163.png)
Encuentre los bancos con el 1% más alto de depósitos.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_236.png)
dat1 = EntityValue["FDICInstitution", "TotalDeposits",
"EntityAssociation"];
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_237.png)
{bottom1percent, top1percent} =
Quantile[values = Values[dat1], {0.01, 0.99}]
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_164.png)
Grafíquelos en un mapa.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_238.png)
GeoListPlot[Keys[Select[dat1, GreaterThan[top1percent]]]]
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_165.png)
La distribución de activos por ciudad notablemente cumple con la ley de Benford.
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_166.png)
Muestre los bancos con el mayor apalancamiento financiero.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_242.png)
dataSet3[TakeLargestBy["FinancialLeverage", 10]]
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_167.png)
Grafique la distribución del apalancamiento financiero.
![Click for copyable input](assets.es/federal-deposit-insurance-corporation-institutiona/In_243.png)
Histogram[dataSet3[All, "FinancialLeverage"], {0, 20, 0.5},
PlotLabel -> "FDIC banks Financial Leverage distribution"]
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_168.png)
Explore gráficamente la relación entre activos, activos de largo plazo y pasivos.
![](assets.es/federal-deposit-insurance-corporation-institutiona/O_169.png)