Yoga para la salud y el conocimiento
Wolfram Knowledgebase incluye un conjunto de datos de posturas de yoga. Como resultado, las relaciones entre las posturas, sus niveles de dificultad, los músculos que involucran, sus duraciones, y muchas otras características pueden ser exploradas y estudiadas de forma programática precisa, simple y potente.
Forme y visualice las relaciones entre posturas de yoga con base en las relaciones de "PreparatoryPoses", comenzando con la postura del escorpión.
![Click for copyable input](assets.es/yoga-for-health-and-knowledge/In_89.png)
poseGraph =
NestGraph[Cases[EntityValue[#, "PreparatoryPoses"], _Entity] &,
Entity["YogaPose", "ScorpionPose"], 4, VertexLabels -> "Name",
VertexLabelStyle -> LightGray]
![](assets.es/yoga-for-health-and-knowledge/O_68.png)
Muestre imágenes esquemáticas de varias posturas.
![Click for copyable input](assets.es/yoga-for-health-and-knowledge/In_90.png)
With[{v = Take[VertexList[poseGraph], 5]},
schm = Rule @@@ Transpose[{v, EntityValue[v, "Schematic"]}]
] // Column
![](assets.es/yoga-for-health-and-knowledge/O_69.png)
Cree un gráfico de posturas agrupadas por "comunidades" que comparten vínculos.
![Click for copyable input](assets.es/yoga-for-health-and-knowledge/In_91.png)
CommunityGraphPlot[EdgeList[poseGraph] /. e_DirectedEdge :> Reverse@e,
VertexLabels -> Placed["Name", Tooltip]]
![](assets.es/yoga-for-health-and-knowledge/O_70.png)
Cuente el número de músculos contraídos en la serie de poses en una secuencia primaria de Ashtanga yoga y grafíquelos frente al número de músculos que participan.
![](assets.es/yoga-for-health-and-knowledge/O_71.png)
Encuentre los músculos que son estirados en la serie de posturas en el saludo al Sol A y visualice los músculos estirados con mayor frecuencia.
![Click for copyable input](assets.es/yoga-for-health-and-knowledge/In_94.png)
muscles = (SortBy[
Tally[DeleteMissing[
Flatten[EntityValue[
Cases[Entity["YogaSequence", "SunSalutationA"][
"PrimaryPoseSequence"], _Entity, Infinity],
"StretchedMuscles"]]]], Last] // Reverse) // Take[#, 20] &
![](assets.es/yoga-for-health-and-knowledge/O_72.png)
Visualice el músculo estirado con mayor frecuencia.
![Click for copyable input](assets.es/yoga-for-health-and-knowledge/In_95.png)
EntityValue[muscles[[1, 1]], "RegionalLocationImage"]
![](assets.es/yoga-for-health-and-knowledge/O_73.png)
Use una clase de entidades implícitamente definida y visualice posturas de yoga de nivel principiante e intermedio que estire la pierna y fortalezca la sección abdominal.
![Click for copyable input](assets.es/yoga-for-health-and-knowledge/In_96.png)
EntityList[
Entity["YogaPose", {"ExperienceLevel" -> "Beginner",
"IntensityLevel" -> "Medium",
"SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"],
"SitesOfImprovedStrength" ->
Entity["AnatomicalStructure", "Abdomen"]}]]
![](assets.es/yoga-for-health-and-knowledge/O_74.png)
Vea imágenes esquemáticas de estas posturas como una asociación de entidades.
![Click for copyable input](assets.es/yoga-for-health-and-knowledge/In_97.png)
EntityList[
Entity["YogaPose", {"ExperienceLevel" -> "Beginner",
"IntensityLevel" -> "Medium",
"SitesOfImprovedMobility" -> Entity["AnatomicalStructure", "Leg"],
"SitesOfImprovedStrength" ->
Entity["AnatomicalStructure", "Abdomen"]}]];
EntityValue[Take[%, 5], "Schematic", "EntityAssociation"]
![](assets.es/yoga-for-health-and-knowledge/O_75.png)
Muestre las posturas avanzadas de yoga que fortalecen los iliopsoas y estiren los músculos isquiotibiales.
![Click for copyable input](assets.es/yoga-for-health-and-knowledge/In_98.png)
EntityValue[
Entity["YogaPose", {"ExperienceLevel" -> "Advanced",
"PrimaryContractedMuscles" ->
Entity["AnatomicalStructure", "Iliopsoas"],
"StretchedMuscles" ->
Entity["AnatomicalStructure",
"SetOfHamstringMuscles"]}], "Schematic", "EntityAssociation"]
![](assets.es/yoga-for-health-and-knowledge/O_76.png)
Encuentre secuencias de yoga con duraciones entre 30 y 60 minutos.
![Click for copyable input](assets.es/yoga-for-health-and-knowledge/In_99.png)
EntityList@
Entity["YogaSequence", {"EstimatedDuration" ->
Quantity[ Interval[{30, 60}], "Minutes"]}]
![](assets.es/yoga-for-health-and-knowledge/O_77.png)