G 환원을 이용한 정적분 계산
MeijerG로 함수를 나타내는 것으로, 양의 실수에서 곱의 계산이 가능하게 됩니다.
함수 곱의 적분을 MeijerG 함수로 나타내는 규칙을 생성합니다.
In[1]:=
![Click for copyable input](assets.ko/compute-definite-integrals-using-g-reduction/In_146.png)
IntegrateMeijerG[f_ g_, {z_, 0, Infinity}] /; FreeQ[{f, g}, MeijerG] :=
IntegrateMeijerG[
MeijerGReduce[f, z] MeijerGReduce[g, z], {z, 0, Infinity}]
이 적분은 정확히 하나의 MeijerG 식으로 나타낼 수 있습니다.
In[2]:=
![Click for copyable input](assets.ko/compute-definite-integrals-using-g-reduction/In_147.png)
IntegrateMeijerG[\[Alpha]_ Inactive[MeijerG][{a_, b_}, {c_,
d_}, \[Omega]_. z_] Inactive[MeijerG][{e_, f_}, {g_,
h_}, \[Eta]_. z_], {z_, 0, Infinity}] /;
FreeQ[{\[Alpha], \[Omega], \[Eta]},
z] := \[Alpha] MeijerG[{Join[-c, e], Join[f, d]}, {Join[-a, g],
Join[h, -b]}, \[Eta]/\[Omega]]
를 평가하는 체계를 적용합니다.
In[3]:=
![Click for copyable input](assets.ko/compute-definite-integrals-using-g-reduction/In_148.png)
Plot[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, 10}, Filling -> Axis,
PlotRange -> All]
Out[3]=
![](assets.ko/compute-definite-integrals-using-g-reduction/O_81.png)
In[4]:=
![Click for copyable input](assets.ko/compute-definite-integrals-using-g-reduction/In_149.png)
IntegrateMeijerG[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}]
Out[4]=
![](assets.ko/compute-definite-integrals-using-g-reduction/O_82.png)
Integrate을 사용하여 동일한 결과를 얻습니다.
In[5]:=
![Click for copyable input](assets.ko/compute-definite-integrals-using-g-reduction/In_150.png)
Integrate[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}]
Out[5]=
![](assets.ko/compute-definite-integrals-using-g-reduction/O_83.png)
답은 완전히 다른 것처럼 보이지만 실제로는 동일합니다.
In[6]:=
![Click for copyable input](assets.ko/compute-definite-integrals-using-g-reduction/In_151.png)
IntegrateMeijerG[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}];
Integrate[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}];
FullSimplify[% == %%]
Out[6]=
![](assets.ko/compute-definite-integrals-using-g-reduction/O_84.png)