G還元を使った定積分を計算する
MeijerGで関数を表すことで,正の実数上での積の計算が可能になる.
関数の積の積分をMeijerG関数で表す規則を生成する.
In[1]:=
![Click for copyable input](assets.ja/compute-definite-integrals-using-g-reduction/In_145.png)
IntegrateMeijerG[f_ g_, {z_, 0, Infinity}] /; FreeQ[{f, g}, MeijerG] :=
IntegrateMeijerG[
MeijerGReduce[f, z] MeijerGReduce[g, z], {z, 0, Infinity}]
この積分は,厳密に1つのMeijerG式で表すことができる.
In[2]:=
![Click for copyable input](assets.ja/compute-definite-integrals-using-g-reduction/In_146.png)
IntegrateMeijerG[\[Alpha]_ Inactive[MeijerG][{a_, b_}, {c_,
d_}, \[Omega]_. z_] Inactive[MeijerG][{e_, f_}, {g_,
h_}, \[Eta]_. z_], {z_, 0, Infinity}] /;
FreeQ[{\[Alpha], \[Omega], \[Eta]},
z] := \[Alpha] MeijerG[{Join[-c, e], Join[f, d]}, {Join[-a, g],
Join[h, -b]}, \[Eta]/\[Omega]]
を評価するスキームを適用する.
In[3]:=
![Click for copyable input](assets.ja/compute-definite-integrals-using-g-reduction/In_147.png)
Plot[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, 10}, Filling -> Axis,
PlotRange -> All]
Out[3]=
![](assets.ja/compute-definite-integrals-using-g-reduction/O_81.png)
In[4]:=
![Click for copyable input](assets.ja/compute-definite-integrals-using-g-reduction/In_148.png)
IntegrateMeijerG[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}]
Out[4]=
![](assets.ja/compute-definite-integrals-using-g-reduction/O_82.png)
Integrateを使って同じ結果を得る.
In[5]:=
![Click for copyable input](assets.ja/compute-definite-integrals-using-g-reduction/In_149.png)
Integrate[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}]
Out[5]=
![](assets.ja/compute-definite-integrals-using-g-reduction/O_83.png)
答は全く異なるように見えるが,等価である.
In[6]:=
![Click for copyable input](assets.ja/compute-definite-integrals-using-g-reduction/In_150.png)
IntegrateMeijerG[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}];
Integrate[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}];
FullSimplify[% == %%]
Out[6]=
![](assets.ja/compute-definite-integrals-using-g-reduction/O_84.png)