Calculez les intégrales à l'aide de la réduction G
Exprimer les fonctions en termes de MeijerG vous permet de calculer leur produit sur les réels positifs.
Créez une règle pour exprimer l'ensemble d'un produit de fonctions en termes de fonctions MeijerG.
In[1]:=
![Click for copyable input](assets.fr/compute-definite-integrals-using-g-reduction/In_145.png)
IntegrateMeijerG[f_ g_, {z_, 0, Infinity}] /; FreeQ[{f, g}, MeijerG] :=
IntegrateMeijerG[
MeijerGReduce[f, z] MeijerGReduce[g, z], {z, 0, Infinity}]
Cette intégrale peut être exprimée exactement en termes d'une expression unique à MeijerG.
In[2]:=
![Click for copyable input](assets.fr/compute-definite-integrals-using-g-reduction/In_146.png)
IntegrateMeijerG[\[Alpha]_ Inactive[MeijerG][{a_, b_}, {c_,
d_}, \[Omega]_. z_] Inactive[MeijerG][{e_, f_}, {g_,
h_}, \[Eta]_. z_], {z_, 0, Infinity}] /;
FreeQ[{\[Alpha], \[Omega], \[Eta]},
z] := \[Alpha] MeijerG[{Join[-c, e], Join[f, d]}, {Join[-a, g],
Join[h, -b]}, \[Eta]/\[Omega]]
Appliquez le schéma pour évaluer .
In[3]:=
![Click for copyable input](assets.fr/compute-definite-integrals-using-g-reduction/In_147.png)
Plot[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, 10}, Filling -> Axis,
PlotRange -> All]
Out[3]=
![](assets.fr/compute-definite-integrals-using-g-reduction/O_81.png)
In[4]:=
![Click for copyable input](assets.fr/compute-definite-integrals-using-g-reduction/In_148.png)
IntegrateMeijerG[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}]
Out[4]=
![](assets.fr/compute-definite-integrals-using-g-reduction/O_82.png)
Obtenez le même résultat en utilisant Integrate.
In[5]:=
![Click for copyable input](assets.fr/compute-definite-integrals-using-g-reduction/In_149.png)
Integrate[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}]
Out[5]=
![](assets.fr/compute-definite-integrals-using-g-reduction/O_83.png)
Bien que la réponse semble tout à fait différente, elle est équivalente.
In[6]:=
![Click for copyable input](assets.fr/compute-definite-integrals-using-g-reduction/In_150.png)
IntegrateMeijerG[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}];
Integrate[(1 + z)^(-3/2) EllipticK[-2 z], {z, 0, Infinity}];
FullSimplify[% == %%]
Out[6]=
![](assets.fr/compute-definite-integrals-using-g-reduction/O_84.png)