Daten aus Internet-Quellen
Laden Sie die täglichen Temperatur-Mittelwerte der Great Lakes in den USA der letzten Jahre.
In[1]:=
![Click for copyable input](assets.de/data-from-internet-sources/In_111.png)
rawdata =
Import["http://coastwatch.glerl.noaa.gov/ftp/glsea/avgtemps/glsea-\
temps_1024.dat", "Data"];
Die Beobachtungen beginnen ab Zeile 11.
In[2]:=
![Click for copyable input](assets.de/data-from-internet-sources/In_112.png)
rawdata[[;; 11]]
Out[2]=
![](assets.de/data-from-internet-sources/O_61.png)
In[3]:=
![Click for copyable input](assets.de/data-from-internet-sources/In_113.png)
obs = rawdata[[11 ;;]];
Die Zahl der Beobachtungen.
In[4]:=
![Click for copyable input](assets.de/data-from-internet-sources/In_114.png)
Length[obs]
Out[4]=
![](assets.de/data-from-internet-sources/O_62.png)
Erstellen Sie die Liste der Seen.
In[5]:=
![Click for copyable input](assets.de/data-from-internet-sources/In_115.png)
lakes = {"Superior", "Michigan", "Huron", "Erie", "Ontario",
"St. Clair"};
Den kompletten Wolfram Language-Input zeigen
Out[6]=
![](assets.de/data-from-internet-sources/O_63.png)
Erstellen Sie Datumsangaben, die als Zeitstempel in TimeSeries dienen.
In[7]:=
![Click for copyable input](assets.de/data-from-internet-sources/In_117.png)
dates = Table[
DatePlus[{obs[[k, 1]], 1, 1}, Quantity[obs[[k, 2]], "Days"]], {k,
1, Length[obs]}];
Speichern Sie mit QuantityArray die Temperaturen und die Einheit.
In[8]:=
![Click for copyable input](assets.de/data-from-internet-sources/In_118.png)
values = QuantityArray[obs[[All, 3 ;;]], "DegreesCelsius"]
Out[8]=
![](assets.de/data-from-internet-sources/O_64.png)
Speichern Sie die Liste der Seen als MetaInformation, die später abgerufen werden kann, z.B. zur Erstellung von Legenden für das Diagramm.
In[9]:=
![Click for copyable input](assets.de/data-from-internet-sources/In_119.png)
ts = TimeSeries[values, {dates},
MetaInformation -> {"Lakes" -> lakes}]
Out[9]=
![](assets.de/data-from-internet-sources/O_65.png)
In[10]:=
![Click for copyable input](assets.de/data-from-internet-sources/In_120.png)
DateListPlot[ts, PlotLegends -> ts["Lakes"], PlotTheme -> "Detailed",
FrameLabel -> Automatic]
Out[10]=
![](assets.de/data-from-internet-sources/O_66.png)
Untersuchen Sie die deskriptive Statistik jedes Sees.
In[11]:=
![Click for copyable input](assets.de/data-from-internet-sources/In_121.png)
stats = {Min, Max, Mean, Median, StandardDeviation};
summary[lake_] := Map[#[lake] &, stats]
In[12]:=
![Click for copyable input](assets.de/data-from-internet-sources/In_122.png)
TableForm[
Table[summary[ts["PathComponent", k]], {k, 1, Length[lakes]}],
TableHeadings -> {lakes, stats}]
Out[12]//TableForm=
![](assets.de/data-from-internet-sources/O_67.png)