Données provenant de sources Internet
Téléchargez les températures moyennes quotidiennes pour l'année écoulée pour les Grands Lacs.
In[1]:=
![Click for copyable input](assets.fr/data-from-internet-sources/In_111.png)
rawdata =
Import["http://coastwatch.glerl.noaa.gov/ftp/glsea/avgtemps/glsea-\
temps_1024.dat", "Data"];
Les observations commencent à partir de la ligne 11.
In[2]:=
![Click for copyable input](assets.fr/data-from-internet-sources/In_112.png)
rawdata[[;; 11]]
Out[2]=
![](assets.fr/data-from-internet-sources/O_61.png)
In[3]:=
![Click for copyable input](assets.fr/data-from-internet-sources/In_113.png)
obs = rawdata[[11 ;;]];
Le nombre d'observations.
In[4]:=
![Click for copyable input](assets.fr/data-from-internet-sources/In_114.png)
Length[obs]
Out[4]=
![](assets.fr/data-from-internet-sources/O_62.png)
Définissez la liste des lacs.
In[5]:=
![Click for copyable input](assets.fr/data-from-internet-sources/In_115.png)
lakes = {"Superior", "Michigan", "Huron", "Erie", "Ontario",
"St. Clair"};
Afficher l'entrée complète de Wolfram Language
Out[6]=
![](assets.fr/data-from-internet-sources/O_63.png)
Créez des dates qui serviront d'horodotage dans la TimeSeries.
In[7]:=
![Click for copyable input](assets.fr/data-from-internet-sources/In_117.png)
dates = Table[
DatePlus[{obs[[k, 1]], 1, 1}, Quantity[obs[[k, 2]], "Days"]], {k,
1, Length[obs]}];
Utilisez QuantityArray pour stocker les températures et l'unité.
In[8]:=
![Click for copyable input](assets.fr/data-from-internet-sources/In_118.png)
values = QuantityArray[obs[[All, 3 ;;]], "DegreesCelsius"]
Out[8]=
![](assets.fr/data-from-internet-sources/O_64.png)
Stockez la liste des lacs en tant que MetaInformation qui peut être récupéré plus tard, par exemple, pour créer des légendes de tracé.
In[9]:=
![Click for copyable input](assets.fr/data-from-internet-sources/In_119.png)
ts = TimeSeries[values, {dates},
MetaInformation -> {"Lakes" -> lakes}]
Out[9]=
![](assets.fr/data-from-internet-sources/O_65.png)
In[10]:=
![Click for copyable input](assets.fr/data-from-internet-sources/In_120.png)
DateListPlot[ts, PlotLegends -> ts["Lakes"], PlotTheme -> "Detailed",
FrameLabel -> Automatic]
Out[10]=
![](assets.fr/data-from-internet-sources/O_66.png)
Étudiez les statistiques descriptives pour chaque lac.
In[11]:=
![Click for copyable input](assets.fr/data-from-internet-sources/In_121.png)
stats = {Min, Max, Mean, Median, StandardDeviation};
summary[lake_] := Map[#[lake] &, stats]
In[12]:=
![Click for copyable input](assets.fr/data-from-internet-sources/In_122.png)
TableForm[
Table[summary[ts["PathComponent", k]], {k, 1, Length[lakes]}],
TableHeadings -> {lakes, stats}]
Out[12]//TableForm=
![](assets.fr/data-from-internet-sources/O_67.png)