インターネットソースからのデータ
五大湖の過去1年の日々の平均気温をダウンロードする.
In[1]:=
![Click for copyable input](assets.ja/data-from-internet-sources/In_111.png)
rawdata =
Import["http://coastwatch.glerl.noaa.gov/ftp/glsea/avgtemps/glsea-\
temps_1024.dat", "Data"];
観測は第11行から始まる.
In[2]:=
![Click for copyable input](assets.ja/data-from-internet-sources/In_112.png)
rawdata[[;; 11]]
Out[2]=
![](assets.ja/data-from-internet-sources/O_61.png)
In[3]:=
![Click for copyable input](assets.ja/data-from-internet-sources/In_113.png)
obs = rawdata[[11 ;;]];
観測の回数.
In[4]:=
![Click for copyable input](assets.ja/data-from-internet-sources/In_114.png)
Length[obs]
Out[4]=
![](assets.ja/data-from-internet-sources/O_62.png)
湖のリストを定義する.
In[5]:=
![Click for copyable input](assets.ja/data-from-internet-sources/In_115.png)
lakes = {"Superior", "Michigan", "Huron", "Erie", "Ontario",
"St. Clair"};
完全なWolfram言語入力を表示する
Out[6]=
![](assets.ja/data-from-internet-sources/O_63.png)
TimeSeriesのタイムスタンプとなる日付を生成する.
In[7]:=
![Click for copyable input](assets.ja/data-from-internet-sources/In_117.png)
dates = Table[
DatePlus[{obs[[k, 1]], 1, 1}, Quantity[obs[[k, 2]], "Days"]], {k,
1, Length[obs]}];
QuantityArrayを使って気温と単位を保存する.
In[8]:=
![Click for copyable input](assets.ja/data-from-internet-sources/In_118.png)
values = QuantityArray[obs[[All, 3 ;;]], "DegreesCelsius"]
Out[8]=
![](assets.ja/data-from-internet-sources/O_64.png)
湖のリストを,後で,例えばプロット凡例を作成する等のために取り出すことのできるMetaInformationとして保存する.
In[9]:=
![Click for copyable input](assets.ja/data-from-internet-sources/In_119.png)
ts = TimeSeries[values, {dates},
MetaInformation -> {"Lakes" -> lakes}]
Out[9]=
![](assets.ja/data-from-internet-sources/O_65.png)
In[10]:=
![Click for copyable input](assets.ja/data-from-internet-sources/In_120.png)
DateListPlot[ts, PlotLegends -> ts["Lakes"], PlotTheme -> "Detailed",
FrameLabel -> Automatic]
Out[10]=
![](assets.ja/data-from-internet-sources/O_66.png)
各湖の記述統計量を調べる.
In[11]:=
![Click for copyable input](assets.ja/data-from-internet-sources/In_121.png)
stats = {Min, Max, Mean, Median, StandardDeviation};
summary[lake_] := Map[#[lake] &, stats]
In[12]:=
![Click for copyable input](assets.ja/data-from-internet-sources/In_122.png)
TableForm[
Table[summary[ts["PathComponent", k]], {k, 1, Length[lakes]}],
TableHeadings -> {lakes, stats}]
Out[12]//TableForm=
![](assets.ja/data-from-internet-sources/O_67.png)